$>
$>type filename.rpt

Node Name = OWS1
This computer is all clear :-)

Node Name = OWS2
This computer still contains data of types a, b, & c.

Node Name = OWS3
This computer still contains data of type c.

Node Name = OWS4
This computer is all clear :-)



$>type test1.com

$!-------<>-------
$!...do housekeeping stuff here
$ open/read rpt filename.rpt
$!...
$ write sys$output ""
$ write sys$output "Node Data-Status: ''f$time()'"
$ write sys$output ""
$loop1:
$ c1 = ""
$ c2 = ""
$ c3 = ""
$ cnt = 0
$!
$loop2:
$ read/end=finish rpt inrec
$ if f$extract(0,4,inrec) .eqs. "Node"
$  then
$    nodex = inrec - "Node Name = "
$    read/end=error1 rpt inrec
$    if f$extract(0,4,inrec) .eqs. "This"
$      then
$        statusx = inrec - "This computer" -
         - "is all " - " :-)" -
         - "still contains data of type" -
         - "s" - "& "
$        cnt = cnt + 1
$        c'cnt' = f$fao("!6AS!10AS",nodex,statusx)
$      else
$        goto error1 !missing record
$      endif
$    goto loop2 !skip blank lines
$  endif
$!
$ if cnt .lt. 3 then goto loop2
$ call showit
$ goto loop1
$!
$finish:
$ if cnt then call showit
$! display whatever eoj data you want.
$ write sys$output ""
$ read/prompt="Press ENTER " sys$command inp
$ goto quit
$!
$error1:
$! incorrect or missing report record,
$! display error message and ask for ack.
$!
$quit:
$ close rpt
$ exit
$!
$showit: subroutine
$ write sys$output f$fao("  !#(25AS)",cnt,c1,c2,c3)
$exit
$endsubroutine
$!-------<>-------

$>@test1

Node Data-Status: 14-MAR-2006 16:30:28.56

  OWS1   clear             OWS2    a, b, c.         OWS3    c.               
  OWS4   clear             

Press ENTER 

$>