$!
$! File:        SYS$MANAGER:DISK_MOUNTS.COM
$!
$! Function:    Mount/Dismount  disks on XYZZY1/P2/C1/PQ, PLUGH1/D2/DQ, PLOVR1/2
$!
$! Invoked by:  SYS$MANAGER:SYSTARTUP_VMS.COM
$!
$! Parameters:  logical names
$!              DISK_MOUNTS_FUNCTION:   MOUNT - mount all available volumes
$!                                      DISMOUNT - dismount all available volumes
$!                                      DISMOUNT_MEMBERS - dismount selected members of shadowsets
$!                                      MOUNT_NOWRITE - mount the device(s) privately /NOWRITE
$!              DISK_MOUNTS_NODES:      1 or more nodename(s) in comma seperated list to limit
$!                                      action of the selected function
$!
$!  Control Parameters:
$!
$!  Logical names:
$!
$!  DISK_MOUNTS_FUNCTION:       MOUNT[DEF], DISMOUNT, DISMOUNT_MEMBERS, MOUNT_NOWRITE
$!  DISK_MOUNTS_NODES:          list of nodes hosting devices to mount/dismount (def = all)
$!  DISK_MOUNTS_VOLUMES:        list of volume names to affect
$!  DISK_MOUNTS_DEVICES:        list of device names to affect
$!
$!
$!
$! History:     Created 11/30/97 [bkf]
$!
$! 31-Aug-2005  R.L. Boyd       Modified to parameterized function for mount/dismount
$! 19-Dec-2006  R.L. Boyd       Modify system disk mounts to ensure volume label short name gets created
$!
$!================================================================================
$!
$ Set NoOn
$ null = ""
$ bl = " "
$ comma = ","
$ wait_delta = "0:0:10.0"
$ wait_threshold = "0-0:1:0"
$ who_am_i = f$element(0,";",f$environment("procedure")) ! latest version
$ who_am_i_exactly = f$environment("procedure") ! this very procedure
$ where_am_i = f$parse("A.B;0",who_am_i,,,"syntax_only")-"A.B;0"
$! show symbol where_am_i
$ My_root = f$parse(where_am_i,,,,"NO_CONCEAL")-".;" -"][" - "]" + "."
$ my_name = f$parse(who_am_i,,,"NAME")
$!
$ if f$type(nodename).eqs."" then $ nodename = f$edit(f$getsyi("NODENAME"),"TRIM")
$!
$ vms_version = f$edit(f$getsyi("VERSION"),"TRIM")
$!
$ SAY        :=  Write SYS$OUTPUT
$ say   = say +bl+""""+my_name+"-I,"",f$time(),bl,"
$ if f$verify() then $ show symbol say
$!
$ function = f$trnlnm("DISK_MOUNTS_FUNCTION")
$ if function.eqs."" then $ function = "MOUNT"
$!
$ node_selection = f$trnlnm("DISK_MOUNTS_NODES")
$!
$ VOLUME_SELECTION = f$trnlnm("DISK_MOUNTS_VOLUMES")
$ if volume_selection.nes.""
$ then
$   volume_selection = F$EDIT(volume_selection,"TRIM,COMPRESS,COLLAPSE,UPCASE")
$   volume_selection = ","+volume_selection+","
$ endif
$
$ device_selection = f$trnlnm("DISK_MOUNTS_DEVICES")
$ if device_selection.nes.""
$ then
$   device_selection = F$EDIT(device_selection,"TRIM,COMPRESS,COLLAPSE,UPCASE")
$   device_selection = ","+device_selection+","
$ endif
$!
$ show symbol/local/all
$!
$! Volume list format:  <label>:<logical device name(s)>[,...]
$! <label>_PARAMETERS:  <nodename>:<physical device name(s)>[,...]
$!
$ PLUGH_backup_node = "PLUGH1"
$ XYZZY_backup_node = "XYZZY2"
$ XYZZA_backup_node = "XYZZY2"
$ PLOVR_backup_node = "PLOVR1"
$ TWIST_backup_node = "PLOVR1"
$!
$ nodename = f$edit(f$getsyi("NODENAME"),"TRIM")
$ cluster_name = f$extract(0,5,nodename)
$ backup_node = 'cluster_name'_backup_node
$!
$ Volume_list = "ORAARC:DSA1,ORADAT2:DSA2,ORADAT3:DSA3,ORAIND1:DSA4"+ -
        ",ORATMP:DSA5,ORARBS:DSA6,ORASRC:DSA7,ORADAT1:DSA8,ORAIND2:DSA9" + -
        ",ORASYS:DSA10,ORACODE:DSA11"
$!
$ PLUq_data_volume = "DATA:$2$DKA600"
$ PLUq_sys_volume = "DQ_SYS:$2$DKA500"
$ sysd_volumes = "D1_SYS:$1$DKC100,D2_SYS:$1$DKF100,"+PLUq_sys_volume
$!
$ XYZq_sys_volume = "XYZZYQ_SYSDK:XYZZYQ$DKA0"
$ XYZq_data_volume = "USERDATA:XYZZYQ$DKA100"
$ sysp_volumes = "XYZZY1_SYSDK:$1$DKC100,XYZZY2_SYSDK:$1$DKF100,XYZZA1_SYSDK:$2$DKB100,"+XYZQ_SYS_VOLUME
$!
$ syse_volumes = "SCRATCH:DSA100:SCRATCH2"+ -
        ",ABS_SYSFILS2:$31$DKC100,AXPVMS732:$30$DKB0,ABS:$30$DKB100,USER:$30$DKB200,WEB_BACKUP:$30$DKB300"+ -
        ",BIG_DISK:$30$DKB500,OO_BACKUP:$30$DKB600"+ -
        ",SCRATCH4:$31$DKC400,SCRATCH5:$31$DKC500"
$!
$ cluster_name = f$extract(0,5,nodename)
$!
$ if cluster_name.eqs."XYZZY"
$ then
$ node_defaults = "XYZZY1,XYZZY2,XYZZA1,XYZZYQ"
$!
$   volume_list = volume_list+","+sysp_volumes
$   if nodename.eqs."XYZZYQ" then $ volume_list = XYZq_sys_volume+","+XYZq_data_volume
$!
$   ORAARC_PARAMETERS = "XYZZY1:$1$DKB100,XYZZY2:$1$DKE100,XYZZA1:$2$DKD100"
$   ORADAT2_PARAMETERS = "XYZZY1:$1$DKB200,XYZZY2:$1$DKE200,XYZZA1:$2$DKD300"
$   ORADAT3_PARAMETERS = "XYZZY1:$1$DKB300,XYZZY2:$1$DKE300,XYZZA1:$2$DKD400"
$   ORAIND1_PARAMETERS = "XYZZY1:$1$DKB400,XYZZY2:$1$DKE400,XYZZA1:$2$DKD500"
$   ORATMP_PARAMETERS = "XYZZY1:$1$DKB500,XYZZY2:$1$DKE500,XYZZA1:$2$DKB500"
$   ORARBS_PARAMETERS = "XYZZY1:$1$DKB600,XYZZY2:$1$DKE600,XYZZA1:$2$DKB600"
$   ORASRC_PARAMETERS = "XYZZY1:$1$DKC200,XYZZY2:$1$DKF200,XYZZA1:$2$DKB200"
$   ORADAT1_PARAMETERS = "XYZZY1:$1$DKC300,XYZZY2:$1$DKF300,XYZZA1:$2$DKD200"
$   ORAIND2_PARAMETERS = "XYZZY1:$1$DKC400,XYZZY2:$1$DKF400,XYZZA1:$2$DKD600"
$   ORASYS_PARAMETERS = "XYZZY1:$1$DKC500,XYZZY2:$1$DKF500,XYZZA1:$2$DKB300"
$   ORACODE_PARAMETERS = "XYZZY1:$1$DKC600,XYZZY2:$1$DKF600,XYZZA1:$2$DKB400"
$   XYZZY1_SYSDK_PARAMETERS = ""
$   XYZZA1_SYSDK_PARAMETERS = ""
$   XYZZY2_SYSDK_PARAMETERS = ""
$   XYZZYQ_SYSDK_PARAMETERS = ""
$ endif
$!
$ if cluster_name.eqs."PLUGH"
$ then
$!
$   node_defaults = "PLUGH1,PLUGH2,PLUGHQ"
$   volume_list = volume_list+","+sysd_volumes
$   if f$extract(0,5,nodename).eqs."TWIST" then $ volume_list = volume_list+",SCRATCH:DSA100:SCRATCH2"
$   if nodename.eqs."PLUGHQ" then $ volume_list = PLUq_sys_volume+","+PLUq_data_volume
$   SCRATCH8_PARAMETERS = "PLUGH1:$2$DKA200,PLUGH2:$2$DKA300"
$   ORAARC_PARAMETERS = "PLUGH1:$1$DKB100,PLUGH2:$1$DKE100"
$   ORADAT2_PARAMETERS = "PLUGH1:$1$DKB200,PLUGH2:$1$DKE200"
$   ORADAT3_PARAMETERS = "PLUGH1:$1$DKB300,PLUGH2:$1$DKE300"
$   ORAIND1_PARAMETERS = "PLUGH1:$1$DKB400,PLUGH2:$1$DKE400"
$   ORATMP_PARAMETERS = "PLUGH1:$1$DKB500,PLUGH2:$1$DKE500"
$   ORARBS_PARAMETERS = "PLUGH1:$1$DKB600,PLUGH2:$1$DKE600"
$   ORASRC_PARAMETERS = "PLUGH1:$1$DKC200,PLUGH2:$1$DKF200"
$   ORADAT1_PARAMETERS = "PLUGH1:$1$DKC300,PLUGH2:$1$DKF300"
$   ORAIND2_PARAMETERS = "PLUGH1:$1$DKC400,PLUGH2:$1$DKF400"
$   ORASYS_PARAMETERS = "PLUGH1:$1$DKC500,PLUGH2:$1$DKF500"
$   ORACODE_PARAMETERS = "PLUGH1:$1$DKC600,PLUGH2:$1$DKF600"
$!
$   D1_SYS_PARAMETERS = ""
$   D2_SYS_PARAMETERS = ""
$   DQ_SYS_PARAMETERS = ""
$ endif
$!
$ if cluster_name.eqs."PLOVR"
$ then
$!
$   node_defaults = "PLOVR2,PLOVR1"
$   volume_list = syse_volumes
$   SCRATCH_PARAMETERS = "PLOVR2:$31$DKC200,PLOVR2:$31$DKC300"
$!
$ endif
$!
$ if node_selection .eqs. ""
$ then
$       node_selection = node_defaults
$ endif
$!
$ show symbol volume_list
$ show symbol *_parameters
$!
$ node_selection = f$edit(node_selection,"TRIM,COLLAPSE")
$!
$ inode = 0
$NODE_LOOP:
$ nxt_node = f$edit(f$element(inode,",",node_selection),"TRIM")-":"-":"
$ if nxt_node.nes.","
$ then
$       inode= 1+inode
$       if nxt_node.nes.""
$       then
$         disk_include_'nxt_node' = 1
$       endif
$       goto NODE_LOOP
$ endif
$ if f$verify() then $ show symbol disk_include*
$!
$ MOUNT_CMD  =  "Mount /system /noassist /norebuild"
$ mount_CMD_SHAD = MOUNT_CMD
$ if vms_version .ges. "V7.2-2" then $ minicopy = "/POLICY=MINICOPY"
$ ALT_MOUNT_CMD_SHAD = MOUNT_CMD_SHAD
$ MOUNT_CMD_SHAD = MOUNT_CMD_SHAD + "''minicopy'"
$ MOUNT_DISK = "CALL MOUNT_DISK "
$ MOUNT_SHADOW = "CALL MOUNT_SHADOW "
$!
$ Say "Executing ",who_am_i_exactly
$!
$ SAY function,"ing all disks"
$!
$ Set NoOn
$ if f$type(startup_p1).eqs."" then -
$       startup_p1 = f$trnlnm("STARTUP$P1","LNM$STARTUP_TABLE")
$!
$ if p1.eqs."UPGRADE" .or. startup_p1.eqs."UPGRADE" .or. -
        p1.eqs."MINIMUM" .or. startup_p1.eqs."MIN"
$ then  ! upgrade or minimum boot
$       say "***"
$       say "* skipping disk ",function,"s due to minimum/upgrade boot: P1:",p1," / STARTUP_P1:",startup_p1
$       say "* ",f$time()
$       say "***"
$       goto EXIT
$ endif !
$!
$! normal action
$!
$   if volume_selection.eqs.""
$   then $  volume_announce = volume_list
$   else $  volume_announce = volume_selection
$   endif
$   say "***"
$
$   volume_message = f$fao("* attempting to !AS (!AS::!AS) disks",function,node_selection,volume_announce)
$   write/symbol sys$output volume_message
$   say "* ",f$time()
$   say "***"
$!
$   if ( nodename .eqs. "XYZZY2" .or. nodename .eqs. "PLUGH1")
$   then $ remote_add = MOUNT_DISK
$   else $ remote_add = MOUNT_CMD
$   endif
$!
$! These are the "normal" disk mounts, with all 3 shadow set members included.
$!
$ if ( 1 )
$ then ! not a Q NODE
$!
$!
$ iv = 0
$VOLUME_LOOP:
$!
$ nxt_volume = f$edit(f$element(iv,",",volume_list),"TRIM")
$ if nxt_volume.nes.","
$ then ! another volume
$   iv = 1+iv
$   if nxt_volume.nes.""
$   then ! volume is non-null
$     vol_name = f$element(0,":",nxt_volume)
$     vol_device = f$element(1,":",nxt_volume)
$     vol_label = f$element(2,":",nxt_volume)
$     if vol_label.eqs.":" then $ vol_label = vol_name
$     vol_shadow = f$extract(0,2,vol_device).eqs."DS"
$     if (vol_name.nes."" .and. vol_name.nes.":") .and. (vol_device.nes."" .and. vol_device.nes.":")
$     then ! volume has a name and device
$!
$! If either selection list present, check for inclusion
$!
$       if volume_selection .nes. ""
$       then
$         vol_name = f$edit(vol_name,"TRIM,UPCASE")
$         if f$locate(","+vol_name+",",volume_selection).ge.f$length(volume_selection) then $ goto VOLUME_LOOP
$         say "Volume ",vol_name," selected for processing"
$       endif
$       if device_selection .nes. ""
$       then
$         vol_device = f$edit(vol_device,"TRIM,UPCASE")
$         if f$locate(","+vol_device+",",device_selection).ge.f$length(device_selection) then $ goto VOLUME_LOOP
$         say "Volume ",vol_device," selected for processing"
$       endif
$       'vol_name'_device = vol_device
$       'vol_name'_label = vol_label
$!
$! Process the parameter list
$!
$       if f$type('vol_name'_parameters).nes."" .or.  .not.vol_shadow
$       then    ! the parameters are defined
$         if f$type('vol_name'_parameters).eqs.""
$         then $ vol_parameters = ""
$         else $ vol_parameters = 'vol_name'_parameters
$         endif
$         vol_device_list = ""
$         ip = 0
$PARAMETER_LOOP:
$         nxt_param = f$element(ip,",",vol_parameters)
$         if nxt_param .nes. ","
$         then ! parameter
$           ip = 1+ip
$           if vol_shadow
$           then
$               nxt_node = f$element(0,":",nxt_param)
$               nxt_device = f$element(1,":",nxt_param)
$               if f$type(disk_include_'nxt_node').nes.""
$               then ! non-null node
$                 if disk_include_'nxt_node'
$                 then ! the selected node is "included"
$                   if vol_device_list .eqs.""
$                   then ! list is non-null
$                     vol_device_list = nxt_device+":"
$                   else ! no list -- use primay device name
$                     vol_device_list = vol_device_list+","+nxt_device+":"
$                   endif ! list is non/null
$                 endif ! node included
$               endif ! non-null node
$           else ! it's a plain disk mount
$!
$           endif ! shadow/plain disk
$           goto PARAMETER_LOOP
$         endif ! parameter
$!
$! If there are any devices selected, Do the requested function
$!
$        if vol_shadow
$        then   ! shadow volume mount
$         if vol_device_list.nes.""
$           then ! non-null device list
$           if function .eqs. "MOUNT"
$           then        ! Mount function
$!            zvfl = f$verify(1)
$             MOUNT_SHADOW 'vol_device': /shadow=('vol_device_list')  'vol_label' 'vol_name'
$!            zvfl = f$verify(zvfl)
$           else  ! Dismount Function
$             if function .eqs. "DISMOUNT_MEMBERS" .or. function .eqs. "MOUNT_NOWRITE"
$             then ! dis/mount one or more individual members of shadow sets
$               if f$locate(",",vol_device_list).ge.f$length(vol_device_list)
$               then ! the list is 1 simple device
$                 if function .eqs."MOUNT_NOWRITE"
$                 then ! MOUNT/NOWRITE -- private mount
$                   MOUNT/NOWRITE/NOSYSTEM 'vol_device_list' 'vol_label'
$                 else ! DISMOUNT_MEMBERS
$                   if f$getdvi(vol_device_list,"MNT")
$                   then ! DISK MOUNTED
$                     if f$getdvi(vol_device_list,"SHDW_MEMBER")
$                     then ! it is a shadow member
$                       DISMOUNT/policy=minicopy=optional 'vol_device_list'
$                     else ! it is NOT a shadow member
$                       DISMOUNT 'vol_device_list'
$                     endif ! SHADOW MEMBER or not
$                   else ! disk is not mounted
$                       say "Device ",vol_device_list," is already dismounted"
$                   endif ! disk mounted
$                 endif ! dismount_members
$                 if $status then -
$                   say function,"ed ",vol_name,"(",vol_device,") member ",vol_device_list
$               else ! there is a list of devices
$                 idisk = 0
$DISMOUNT_LOOP:
$                 nxt_disk = f$element(idisk,",",vol_device_list)
$                 if nxt_disk.nes.","
$                 then ! another disk to dismount
$                   idisk = 1+idisk
$                   if nxt_disk.nes.""
$                   then ! non-null disk device
$                     if f$getdvi(nxt_disk,"MNT")
$                     then ! disk is mounted
$                       if function .eqs."MOUNT_NOWRITE"
$                       then ! MOUNT private
$                         MOUNT/NOWRITE/NOSYSTEM 'nxt_disk' 'vol_label'
$                       else ! DISMOUNT member
$                         if f$getdvi(nxt_disk,"SHDW_MEMBER")
$                         then ! shadow member
$                           DISMOUNT/POLICY=MINICOPY=OPTIONAL 'nxt_disk'
$                         else ! non-shadow member
$                           DISMOUNT 'nxt_disk'
$                         endif ! SHADOW MEMBER / NOT
$                       endif ! FUNCTION = MOUNT_NOWRITE or DISMOUNT_MEMBER
$                     else ! dismounted already
$                       say "Device ",nxt_disk," is already dismounted"
$                     endif     ! disk is mounted
$                     if $status then $ say function,"ed ",vol_name,"(",vol_device,") member ",nxt_disk
$                   endif ! non-null disk device
$                   goto DISMOUNT_LOOP
$                 endif ! another disk to dismount
$               endif ! list of devices
$             else  ! dismount the whole volume
$               if f$getdvi(vol_device,"MNT") then $ DISMOUNT 'vol_device':
$               if $status then $ say FUNCTION,"ed ",vol_name,"(",vol_device,")"
$             endif ! dismount members/volume
$!
$           endif ! Mount/Dismount
$         endif ! non-null device list
$!
$        else   ! plain disk
$           if function.eqs. "MOUNT"
$           then ! Mount non-shadow disk
$               call poll 'vol_device':'vol_label' "" "" 'vol_label'_status 'vol_name'
$           else ! dismount non-shadow disk
$             if function.EQS."DISMOUNT" .and. f$getdvi(vol_device,"MNT")
$             then ! mounted
$               dismount 'vol_device'
$               if $status then $ say FUNCTION,"ed ",vol_name,"(",vol_device,")"
$             else ! not mounted
$               say "[",function,"] Volume ",vol_name,"(",vol_device,") was not mounted"
$             endif
$           endif ! Mount/Dismount non-shadow disk
$        ENDIF  ! SHADOW/PLAIN DISK
$       else ! no parameters defined
$         say "Volume ",vol_name," has NO parameters defined, volume skipped."
$       endif ! parameters defined
$     endif ! volume name and device
$   endif ! volume non-null
$   goto VOLUME_LOOP
$ endif ! another volume
$!
$!
$! SET VERIFY
$!
$! Temporary change to mount procedure for weekend of 4/23-4/24 RL Boyd
$!
$! MOUNT_SHADOW dsA11:   /shadow = ($1$DKC600:, $1$DKF600:)  oraCODE
$!
$ if f$search("sys$startup:disk_sites.com;").nes.""
$ then ! set disk site values for shadowing
$   zvfl=f$verify(0)
$   @sys$startup:disk_sites
$   zvfl=f$verify(zvfl)
$ endif ! set disk site values
$!
$ ENDIF ! not XYZZYQ
$!
$ if function .eqs."MOUNT"
$ then
$!
$! set verify
$!
$ if cluster_name .eqs. "XYZZY" .or. cluster_name .eqs."XYZZA"
$ then
$   if f$type(XYZZY1_SYSDK_DEVICE).nes."" then -
$   Mount_XYZZY1_SYS = remote_add+" "+XYZZY1_SYSDK_DEVICE+" "+XYZZY1_SYSDK_LABEL+" "+XYZZY1_SYSDK_LABEL
$   if f$type(XYZZA1_SYSDK_DEVICE).nes."" then -
$   Mount_XYZZA1_SYS = remote_add+" "+XYZZA1_SYSDK_DEVICE+" "+XYZZA1_SYSDK_LABEL+" "+XYZZA1_SYSDK_LABEL
$   if f$type(XYZZYQ_SYSDK_DEVICE).nes."" then -
$   Mount_XYZZYQ_SYS = remote_add+" "+XYZZYQ_SYSDK_DEVICE+" "+XYZZYQ_SYSDK_LABEL+" "+XYZZYQ_SYSDK_LABEL
$ endif
$!
$ if cluster_name .eqs. "PLUGH"
$ then
$   if f$type(D2_SYS_DEVICE).nes."" then -
$   Mount_PLUGH2_SYS = remote_add+" "+D2_SYS_DEVICE+" "+D2_SYS_LABEL+" "+D2_SYS_LABEL
$   if f$type(DQ_SYS_DEVICE).nes."" then -
$   Mount_PLUGHQ_SYS = remote_add+" "+DQ_SYS_DEVICE+" "+DQ_SYS_LABEL+" "+DQ_SYS_LABEL
$ endif
$!
$ if ( NODENAME .nes. backup_node )
$ then  ! see if backup node is in the cluster
$       back_member = f$getsyi("CLUSTER_MEMBER",backup_node)
$       if back_member
$       then    ! backup node is there, mount the system disk there
$         my_mount = mount_'nodename'_sys
$         @tools$dir:remote_do 'backup_node' "''my_mount'"
$       endif   ! backup_node is present -- mount system disk
$ endif ! see if backup node is present
$!
$ endif ! MOUNT FUNCTION for odd parts
$
$!!! INIT/HEADER=60000/DIR=2000/NOHIGH disk label ! for 4.3 and 2.0 Gbyte disk
$!
$!!! SUBMIT/NOPRINT/NOTIFY/AFTER="+00:30:00" SYS$STARTUP:DISK_REBUILD.COM
$!
$!
$EXIT:
$!
$ Say "Completed ",who_am_i
$!
$ Exit
$!================================================================================
$! SUBROUTINES
$!
$MOUNT_SHADOW: SUBROUTINE
$ shadow_device = p1
$ parameters = p2+bl+p3+bl+p4+bl+p5+bl+p6+bl+p7+bl+p8
$ device_list = f$edit(f$element(1,"(",f$element(0,")",parameters)),"TRIM,COLLAPSE")
$ if f$verify() then $ show symbol device_list
$ t_end = f$cvtime("+"+wait_threshold)
$!
$ if f$getdvi(shadow_device,"EXISTS") then -
$       if f$getdvi(shadow_device,"MNT") then -
$         show device 'shadow_device'
$!
$MOUNT_SHADOW_WAIT_LOOP:
$ all_ready = 1
$ any_ready = 0
$ idev = 0
$DEVICE_LOOP:
$ device = f$element(idev,comma,device_list)
$ if device.nes.comma
$ then  ! next device name
$   idev = 1+idev
$   if idev.nes.null
$   then ! it is a non-null string
$       if f$getdvi(device,"EXISTS")
$       then $  any_ready = any_ready .or. f$getdvi(device,"AVL")
$       else $ all_ready = 0
$       endif
$   endif! non-null device
$   goto DEVICE_LOOP
$ endif ! next device name
$ if f$verify() then $ show symbol *ready*
$ if all_ready
$ then  ! all devices are available
$!
$! Attempt to mount all of the devices
$!
$   MOUNT_CMD_SHAD 'shadow_device' 'parameters'
$   mnt_status = $status
$!
$   if .not. mnt_status
$   then
$       fail_message = f$message(mnt_status,"IDENT")
$       if fail_message .eqs. "REQ_WBM_MERGE"
$       then
$          alert_message = "Shadow Set ''shadow_device' failed to mount with minicopy, mounting with FULL MERGE"
$          request/to=DISK/noreply "''alert_message'"
$          say "''alert_message'"
$          ALT_MOUNT_CMD_SHAD 'shadow_device' 'parameters'
$       else ! some other error
$          fail_message = f$message(mnt_status,"IDENT,TEXT,FACILITY")
$          alert_message = "Shadow Set ''shadow_device' failed to mount with minicopy, message=''fail_message'"
$          request/to=DISK/noreply "''alert_message'"
$          say "''alert_message'"
$       endif
$   else  ! mount succeeded
$          alert_message = "Shadow Set ''shadow_device' mounted successfully"
$          say "''alert_message'"
$!
$   endif ! mount failed for some reason
$
$!
$! Check to see if all the devices came up
$!
$   all_mounted = 1
$   any_mounted = 0
$   idev = 0
$DEVICE_CHECK_LOOP:
$   device = f$element(idev,comma,device_list)
$   if device.nes.comma
$   then        ! next device name
$     idev = 1+idev
$     if idev.nes.null
$     then ! it is a non-null string
$       if f$getdvi(device,"EXISTS")
$       then
$           any_mounted = any_mounted .or. f$getdvi(device,"MNT")
$           all_mounted = all_mounted .and. f$getdvi(device,"MNT")
$       else $ all_mounted = 0
$       endif
$     endif! non-null device
$     goto DEVICE_CHECK_LOOP
$   endif       ! next device name
$   if any_mounted .and. .not. all_mounted then -
$       ALT_MOUNT_CMD_SHAD 'shadow_device' 'parameters'
$ else  ! not all devices ready
$!
$! if the wait time has expired, try to mount what is available
$!
$   if f$cvtime(null).lts.t_end
$   then        ! we are still inside the wait window
$         say "Waiting for ",shadow_device,"(",device_list,") to come online"
$         wait 'wait_delta'
$         goto MOUNT_SHADOW_WAIT_LOOP
$   else        ! we have passed the end of the wait window
$         say "Abandoning wait for all devices of ",shadow_device,"(",device_list,") "
$         if any_ready  ! if at least one drive is ready -- mount it
$         then $ MOUNT_CMD_SHAD 'shadow_device' 'parameters'
$           if .not. $status then -
$           ALT_MOUNT_CMD_SHAD 'shadow_device' 'parameters'
$         else $ say "No devices available to mount ",shadow_device
$         endif ! device available check
$   endif       ! wait window check
$ endif ! some devices are available
$ENDSUBROUTINE
$!
$! MOUNT_DISK:  routine to mount a single disk volume
$!
$MOUNT_DISK: SUBROUTINE
$ device = p1
$ parameters = p2+bl+p3+bl+p4+bl+p5+bl+p6+bl+p7+bl+p8
$ t_end = f$cvtime("+"+wait_threshold)
$MOUNT_WAIT_LOOP:
$ if f$getdvi(device,"EXISTS")
$ then
$   if .not.f$getdvi(device,"MNT")
$   then        ! it isn't mounted yet -- try it now
$       MOUNT_CMD 'device' 'parameters'
$   else
$       say "Device ",device," is already mounted"
$       vol_logical = f$element(0,"/",f$element(1," ",parameters))
$       if f$trnlnm(vol_logical,"LNM$SYSTEM").eqs.""
$       then
$               define/system/executive_mode 'vol_logical'/translation=(terminal,concealed) 'device'
$       endif
$       show device 'device'
$   endif
$ else
$       if f$cvtime(null).lts.t_end
$       then    ! we are still inside the wait window
$         say "Waiting for ",device," to come online"
$         wait 'wait_delta'
$         goto MOUNT_WAIT_LOOP
$       else    ! we passed the end of the wait window
$         say "Abandoning mount wait for ",device," continuing startup"
$       endif   ! wait window check
$ endif
$ENDSUBROUTINE
$!
$! Poll:        subroutine to poll to see if a particular drive comes online
$!
$POLL: subroutine
$    set noon
$    device = p1
$    device_name = f$element(0,":",device)
$    volume_label == f$element(1,":",device)
$    wait_interval = p2
$    if wait_interval .eqs. ""
$    then
$       if f$type(wait_delta).nes.""
$       then $ wait_interval = wait_delta
$       else $ wait_interval = "0:0:1.0"
$       endif
$    endif
$    poll_cnt = p3
$    if poll_cnt .eqs."" then $ poll_cnt = 60
$    status_sym = p4
$    mount_quals = p5
$    'status_sym' == 0
$!
$    poll_begin = f$time()
$POLL_LOOP:
$    IF F$GETDVI(device_name,"EXISTS")
$    THEN
$       if .not. f$GETDVI(device_name,"MNT")
$       then
$         if volume_label .eqs. ""
$         then
$               mount/override 'device_name':
$               volume_label = f$getdvi(device_name,"volnam")
$               dismount 'device_name':
$         endif
$         if poll_cnt.lt. p3
$         then ! show how long we waited
$           wait_time = f$delta_time(poll_begin,f$time())
$           say "***"
$           say "* Waited ",wait_time," for ",device_name," to come online."
$           say "* ",f$time()
$           say "***"
$         endif
$         MOUNT/SYSTEM/NOASSIST 'device_name': 'volume_label' 'mount_quals'
$       else
$       if f$trnlnm(volume_label,"LNM$SYSTEM").eqs.""
$       then
$               define/system/executive_mode 'volume_label'/translation=(terminal,concealed) 'device_name':
$       endif
$         show device 'device_name'
$       endif
$       'status_sym' == $status
$    ELSE
$       if poll_cnt .eq. p3
$       then
$         say "***"
$         say "* Waiting for Device ",device_name," ( ",volume_label," ) "
$         say "* ",f$time()
$         say "***"
$       endif
$       poll_cnt = poll_cnt - 1
$       if poll_cnt .gt. 0
$       then
$         WAIT 00:00:01
$         GOTO POLL_LOOP
$       else
$         say "***"
$         say "* Device ",device_name," ( ",volume_label," ) is not available -- continuing "
$         say "* ",f$time()
$         say "***"
$       endif
$    ENDIF
$POLL_END:
$endsubroutine