$!      REBOOT.COM
$!      ==========
$! Executes a reboot in a detached process so that it can be launched from 
$! any terminal, including a set host or telnet connection.
$! P1 = FAILOVER , will disable autostart
$!
$! THIS FILE MAY NOT BE MODIFIED OUTSIDE THE SYSMGT MAINTENANCE SYSTEM
$!==============================================================================
$ nodename = f$getsy ("nodename")
$ if f$mod() .eqs. "OTHER" .and. f$getj(0,"prcnam") .eqs. "-< Reboot >-"
$ then 
$    GOTO do_it
$ endif
$ if f$ed(p1,"upcase") .eqs. "FAILOVER" then disable autostart/queue
$ inp=f$env("procedure")
$ if f$mod() .eqs. "BATCH" then inp="sys$manager:reboot.com" ! bypass bug
$ run /detach sys$system:loginout -
      /uic = [1,4] -
      /process_name = "-< Reboot >-" -
      /authorize -
      /input = 'inp' -
      /output = sys$common:[sysmgr]reboot_'nodename'.log
$ exit
$
$do_it:
$ set output_rate = 00:00:05
$ @sys$system:shutdown 0 "Reboot" N Y "Immediately" Y "REBOOT_CHECK,REMOVE_NODE"
$ exit