topic Re: parse a file with expressions (*) in Operating System - HP-UX

parse a file with expressions (*)

support_billa — Thu, 05 Jan 2012 14:52:50 GMT

hello,

i have a new question to :

the awk is perfect:

No, "*" is easier:
# Pattern in test.cnf
# Use == for match
awk -v entry1="${entry1}" -v entry2="${entry2}" -v var="${var}" '
($1 == "*" || $1 == entry1) &&
($2 == "*" || $2 == entry2) &&
$3 == var { print "FOUND5:", $0 }' test.cnf

and handle entry in "test.cnf" like:

* entry2

entry entry2

but how can i handle entries with "characters*" like in "test.cnf" :

demo* entry

is it possible to handle entries with "*" and "character*" ([a-z]*) and a exact entry ?

regards

Re: parse a file with expressions (*)

Dennis Handly — Fri, 06 Jan 2012 15:40:03 GMT

>demo* entry

>is it possible to handle entries with "*" and "character*" ([a-z]*) and a exact entry?

I'm not sure what you want? Do you want to treat "*" as a normal character or as a shell pattern match?

Your above awk fragment treats it as a normal char but with special processing, to pretend to be a pattern.

If you want to do more general pattern matching, you would have to use system to invoke a shell.

Or you could convert that pattern into a regex an use awk's ERE to do the matching.

demo* (pattern) == demo.* (regex)

demo? (pattern) == demo. (regex)

Re: parse a file with expressions (*)

support_billa — Mon, 09 Jan 2012 15:01:12 GMT

hello,

If you want to do more general pattern matching, you would have to use system to invoke a shell.
Or you could convert that pattern into a regex an use awk's ERE to do the matching.

demo* (pattern) == demo.* (regex)
demo? (pattern) == demo. (regex)

right, i want to extend "awk" and want to handle

"*"

"demo*"

"demo"

for example

"*" and "demo" is perfect with the awk , but how i handle like "demo*"

regards

Re: parse a file with expressions (*)

Dennis Handly — Tue, 10 Jan 2012 03:48:21 GMT

>I want to extend "awk" and want to handle: "*", "demo*", "demo"

As I suggested, you convert the pattern to a ERE then try matching:

awk -v entry1="${entry1}" -v entry2="${entry2}" -v var="${var}" '
function to_ere(pattern) {
   # convert from *, ? pattern to ERE, add anchors
   gsub("\*", ".*", pattern)
   gsub("\?", ".", pattern)
   pattern = "^" pattern "$"
   return pattern
}
$3 == var {
   ere1 = to_ere($1)
   ere2 = to_ere($2)
   if (entry1 ~ ere1 && entry2 ~ ere2) {
      print "FOUND5:", $0
   }
}' test.cnf

Re: parse a file with expressions (*)

support_billa — Tue, 10 Jan 2012 09:52:58 GMT

thank you very much, perfect solution with ERE ( i learn every day when you post solutions)