topic Re: Script help. in Operating System - HP-UX

Script help.

allanm77 — Tue, 23 Aug 2011 21:59:31 GMT

Hi All,

Created a piece of shell script, want to iterate the curl statement and if condition for multiple Services,boxes combination (within the same script) and send multiple emails if the condition is met.

If possible would prefer this to be converted to perl.

#!/bin/sh

SERVICE1=appnameA
BOX1=boxA.foobar.com
PORT1=5000

curl -s "http://$BOX1:$PORT1/segment/region/phase/dest?app=$SERVICE1" | grep DISABLED
if (`echo $?` eq 0 )
then 
mail -s "$SERVICE1 is down" allanm@foobar.com </dev/null
fi

Thanks,

Allan.

Re: Script help.

James R. Ferguson — Tue, 23 Aug 2011 22:46:40 GMT

@allanm77 wrote:
Hi All,

Created a piece of shell script, want to iterate the curl statement and if condition for multiple Services,boxes combination (within the same script) and send multiple emails if the condition is met.

If possible would prefer this to be converted to perl.

So, place a 'for' loop around the 'curl...if...fi' .

Why do you feel the need to convert this to Perl?

Regards!

...JRF...

Re: Script help.

allanm77 — Tue, 23 Aug 2011 22:59:06 GMT

Thanks JRF!

Its my never ending desire to compare how code works between shell and perl.

Thanks,
Allan.

Re: Script help.

James R. Ferguson — Wed, 24 Aug 2011 12:32:22 GMT

Hi (again) Allan:

How about evaulating the comments here?

http://h30499.www3.hp.com/t5/Languages-and-Scripting/How-to-fasten-nested-quot-for-quot-loops/td-p/5306443

...JRF...

Re: Script help.

allanm77 — Wed, 24 Aug 2011 17:21:38 GMT

Hi JRF,

Evaluated, thanks!

Can you provide the perl equivalent of the shell script..

Thanks,
Allan.

Re: Script help.

James R. Ferguson — Wed, 24 Aug 2011 19:16:24 GMT

@allanm77 wrote:
Hi JRF,
Can you provide the perl equivalent of the shell script..

OK, here's one possibility. I am going to assume that you have some knowledge of Perl and/or that you will dig with this as an example :-)

#!/usr/bin/perl
use strict;
use warnings;

my $SERVICE1 = q(appnameA);
my $BOX1     = q(boxA.foobar.com);
my $PORT1    = 5000;

my $result =
    qx(curl -s "http://$BOX1:$PORT1/segment/region/phase/dest?app=$SERVICE1");
my $rc = $?;

die "Can't fetch URL; return code = ", +($rc >> 8), "\n" unless $rc == 0;

 if ( $result =~ m{DISABLED} ) {
    system qq( mail -s "$SERVICE1 is down" allanm\@foobar.com </dev/null );
}
1;

Regards!

...JRF...

Re: Script help.

allanm77 — Wed, 24 Aug 2011 22:07:59 GMT

Thanks JRF!

One more issue I am thinking of is that we have more than 10 boxes in production and I need to do this on more than 5 apps so it would be wonderful if the solution is better than a for loop, maybe array?

Allan.

Re: Script help.

James R. Ferguson — Thu, 25 Aug 2011 01:55:44 GMT

@allanm77 wrote:
Thanks JRF!

One more issue I am thinking of is that we have more than 10 boxes in production and I need to do this on more than 5 apps so it would be wonderful if the solution is better than a for loop, maybe array?

I like the way your requests grow as I offer a solution for each iteration ;-) Don't forget to evaluate each solution as we go along.

For this last one, we will use a hash for several reasons.

#!/usr/bin/perl
use strict;
use warnings;

my %apps = (
    appnameA => q(boxA.foobar.com),
    appnameB => q(boxB.foobar.com),
    appnameC => q(boxC.foobar.com),
);
    
my $port = 5000;

while ( my ( $service, $box ) = each %apps ) {
    my $url    = qq(http://$box:$port/segment/region/phase/dest?app=$service);
    my $result = qx(curl -s $url);
    my $rc     = $?;

    die "Can't fetch $url; return code = ", +($rc >> 8), "\n" unless $rc == 0;

    if ( $result =~ m{DISABLED} ) {
        system qq
            ( mail -s "$service down on $box" allanm\@foobar.com </dev/null );
    }
}
1;

Notice, among other things, that I have lower-cased the variable names. Upper-case names are generally used for constants.

You can add more items to the hash as necessary.

Regards!

...JRF...

Re: Script help.

James R. Ferguson — Thu, 25 Aug 2011 12:07:16 GMT

Hi (again):

Oops, we really don't want to die() and abandon all processing when we loop through the hash and curl() returns a non-zero value. Instead, replace this line:

die "Can't fetch $url; return code = ", +($rc >> 8), "\n" unless $rc == 0;

...with this:

if ( $rc != 0 ) {
    warn "Can't fetch $url; return code = ", +($rc >> 8), "\n";
    next;
}

This reports the error and continues to process the next hash member.

Regards!

...JRF...

Re: Script help.

allanm77 — Thu, 25 Aug 2011 18:21:58 GMT

Thanks JRF!

Re: Script help.

H.Merijn Brand (procura — Fri, 26 Aug 2011 19:34:17 GMT

Why use external commands if perl supports this though modules extremely well?

#!/usr/bin/perl

use strict;
use warnings;
use LWP;
use LWP::UserAgent;
use Mail::Sendmail;

my %apps = (
    appnameA => "boxA.foobar.com",
    appnameB => "boxB.foobar.com",
    appnameC => "boxC.foobar.com",
    );
my $port = 5000;
my $ua = LWP::UserAgent->new (
    agent      => "Opera/11.00 opera 11",
    cookie_jar => {},
    );

while (my ($service, $box) = each %apps) {
    my $url = qq(http://$box:$port/segment/region/phase/dest?app=$service);
    my $rsp = $ua->request (HTTP::Request->new (GET => $url));

    $rsp->is_success or die "get failed: ", $rsp->status_line, "\n";
    if ($rsp->content =~ m/DISABLED/) {
        sendmail (
            To      => 'allanm@foobar.com',
            From    => 'me@this.box',
            Subject => "$service down on $box",
            Message => "Please fix",
            ) or die $Mail::Sendmail::error;
        }
    }

Re: Script help.

James R. Ferguson — Sun, 28 Aug 2011 13:48:53 GMT

@H.Merijn Brand (procura wrote:
Why use external commands if perl supports this though modules extremely well?

I agree, particularly from a portability standpoint. Of course, Allan is probably running Perl 5.8.8 from the standard HP-UX distributions. He would need to install the LWP::UserAgent (perhaps) and Mail::SendMail from CPAN. While this is trivial, some sites are reticent in these regards :-(

Regards!

...JRF...