topic Re: Perl - calculate time difference in Operating System - Linux

Perl - calculate time difference

Anand_30 — Thu, 25 Aug 2005 15:25:44 GMT

I have to find the time difference between 2 date time of the format 08252005193248 and 08252005193249. The last 6 digits value is that of the time.

I am doing the following:

my $time1 = substr($data[3],9,6);
my $time2 = substr($data[4],9,6);

my $timediff = $time2 - $time1;

if($timediff < 0)
{
$timediff += 60*60*24;
}

But still I am getting time difference in negative.

Please help.

Thanks,
Anand

Re: Perl - calculate time difference

Steven E. Protter — Thu, 25 Aug 2005 15:27:40 GMT

I recommend a time tested tool, created by A. Clay, our fearless point leader.

http://hpux.ws/merijn/caljd-2.2.pl

SEP

Re: Perl - calculate time difference

A. Clay Stephenson — Thu, 25 Aug 2005 15:43:10 GMT

First of all, substr in Perl unlike awk is zero-based rather than one-based but a much better answer is to convert the entire string to epoch seconds so that differences over days can be calculated.
#!/usr/bin/perl -w

use strict;
use Time::Local;

my $t1 = "08252005194248";
my $t2 = "08252005194249";

sub to_seconds
{
use integer;
my $x = $_[0];

my $mo = substr($x,0,2);
my $day = substr($x,2,2);
my $year = substr($x,4,4);
my $hour = substr($x,8,2);
my $minute = substr($x,10,2);
my $second = substr($x,12,2);

my $t = timelocal($second,$minute,$hour,$day,$mo - 1,$year - 1900);
return($t);
}

my $diff = to_seconds($t2) - to_seconds($t1);
printf("Diff = %d seconds\n",$diff);

Re: Perl - calculate time difference

James R. Ferguson — Thu, 25 Aug 2005 15:52:03 GMT

Hi Anand:

Are you running with 'use warnings' or at least '-w' ???

Looking at your code in isolation, this would lead to a negative computation if you data[4] wasn't defined.

Regards!

...JRF...

Re: Perl - calculate time difference

Hein van den Heuvel — Thu, 25 Aug 2005 20:36:05 GMT

Like Clay's solution, but using UNPACK to break down the input strings

---------
use Time::Local;

sub seconds {
($mo,$d,$y,$h,$mi,$s) = unpack 'a2a2a4a2a2a2', $_[0];
return timelocal($s,$mi,$h,$d,$mo - 1,$y - 1900);
}
$t1 = seconds (shift @ARGV);
$t2 = seconds (shift @ARGV);

print $t1 - $t2;
------
$ perl tmp.p 08252005194248 08252005184248
3600
$ perl tmp.p 08252005194248 08242005194248
86400

Hein.