topic Re: Perl: Sort in Operating System - Linux

Perl: Sort

Coolmar — Thu, 12 Oct 2006 08:05:27 GMT

I found this script that I like on these forums. I don't really know perl at all so I am wondering if someone here can help. How can I sort the output by the percentage. So the output would be something like this:

/home/usera (xxxxxxxkb) 45%
/home/userb (xxxxxxxkb) 20%
/home/userc (xxxxxxxkb) 5%

Thanks,

#!/usr/contrib/bin/perl
# Show the percentage of total used space in /home to each user
# 11/18/02 BRS

$home_thresh = 1 ; # won't print if it isn't more than 1%

# Get the size of each users home directory

# sub homes_report {
$home_total = `du -sk /home 2> \/dev\/null`;
($home_total,$nothing) = split(/\s+/,$home_total) ;

print "/home's total usage is $home_total kb \n" ;

foreach (`du -sk /home/* 2> \/dev\/null` ) {
chop ;
($home_kb,$home_dir) = split (/\s+/);
$homes_size{$home_dir} = $home_kb ;
$home_pct = int(($home_kb / $home_total) * 100) ;
if ( $home_pct > $home_thresh ) {
print $home_dir ($home_kb kb) is $home_pct% \n" ;
}
}

Re: Perl: Sort

H.Merijn Brand (procura — Thu, 12 Oct 2006 08:23:54 GMT

This is *very* old perl code. And bad style too

#!/opt/perl/bin/perl

use strict;
use warnings;

# Show the percentage of total used space in /home to each user

my $home_thresh = 1 ; # won't print if it isn't more than 1%

# Get the size of each users home directory

# sub homes_report {
(my $home_total = `du -sk /home 2> /dev/null`) =~ s/\s.*//s;

print "/home's total usage is $home_total kb \n" ;

my %homes;
for (`du -sk /home/* 2>/dev/null`) {
chomp;
my ($home_kb, $home_dir) = split m/\s+/;
$homes{$home_dir}{size} = $home_kb;
my $home_pct = int (($home_kb / $home_total) * 100);
$home_pct > $home_thresh or next;
$homes{$home_dir}{pct} = $home_pct;
}

foreach my $dir (sort { $homes{$b}{pct} <=> $homes{$a}{pct} } keys %homes) {
printf "%6.2f%% %s\n", $homes{$dir}{pct}, $dir;
}

Enjoy, Have FUN! H.Merijn

Re: Perl: Sort

H.Merijn Brand (procura — Fri, 13 Oct 2006 06:01:53 GMT

Vo tried and found a small glitch.
Try this instead

#!/opt/perl/bin/perl

use strict;
use warnings;

my $users = shift || "/users";

# Show the percentage of total used space in /home to each user
my $home_thresh = 1.; # won't print if it isn't more than 1%
# Get the size of each users home directory
# sub homes_report {
(my $home_total = `du -sk $users 2> /dev/null`) =~ s/\s.*//s;
print "$users\'s total usage is $home_total kb \n";
$home_total > 0 or exit;

my %homes;
for (`du -sk $users/* 2>/dev/null`) {
chomp;
my ($home_kb, $home_dir) = split m/\s+/;
$homes{$home_dir}{size} = $home_kb;
my $home_pct = int (($home_kb / $home_total) * 100);
$homes{$home_dir}{pct} = $home_pct;
}
foreach my $dir (sort { $homes{$b}{pct} <=> $homes{$a}{pct} } keys %homes) {
$homes{$dir}{pct} > $home_thresh and
printf "%6.2f%% %s\n", $homes{$dir}{pct}, $dir;
}

Enjoy, Have FUN! H.Merijn

Re: Perl: Sort

Coolmar — Fri, 13 Oct 2006 07:39:45 GMT

Thanks, that second one worked like a charm.

Re: Perl: Sort

V. Nyga — Fri, 13 Oct 2006 07:45:28 GMT

Merijn,

your a genius!!!!!!!!!

Many thanks and 25 pts. from me *1*

Best wishes
see you
Volkmar