topic Re: Decnet traceroute in Operating System - OpenVMS

Decnet traceroute

Sunil Kunnel — Tue, 08 Apr 2008 08:39:43 GMT

Like traceroute in TCPIP, is there a any tool in DECNET to trace the route from one host to another? The MC NCP sho know nodes shows the next node address.

Re: Decnet traceroute

Volker Halle — Tue, 08 Apr 2008 08:57:19 GMT

Sunil,

there is no such tool in the DECnet or DECnet-Plus product for OpenVMS.

You would need to use a sequence of NCP SHOW NODE x and NCP TELL y SHOW NODE x commands to manually follow each hop to the destination system. It will get more complicated, if you have both DECnet IV and DECnet V systems around.

There may have been a DEC-internal tool (DCL procedure) for this in the DECnet Phase IV time frame.

Volker.

Re: Decnet traceroute

labadie_1 — Tue, 08 Apr 2008 09:08:10 GMT

As Volker said, mc ncp tell...
will draw a Decnet traceroute, IF mc ncp tell is authorized on the various Decnet nodes.

I remember a good laugh when I discovered, using this method, why a Decnet copy in Paris (about 1 kilometer) was so long: the path was France -> Hongkong -> UK -> France

:-)

Re: Decnet traceroute

Sunil Kunnel — Tue, 08 Apr 2008 09:10:08 GMT

thank you.

Re: Decnet traceroute

Sunil Kunnel — Tue, 08 Apr 2008 09:17:23 GMT

I am confused. Suppose If I want to get trace from, say Node X to Node Y what would be the command?. I am getting tomany option when i give a MC ncp tell command.

Re: Decnet traceroute

Volker Halle — Tue, 08 Apr 2008 09:23:15 GMT

Sunil,

if you want to know the DECnet route to node x:

$ MCP NCP SHOW NODE x

This will show the next node, let's say 'y'

$ MC NCP TELL y SHOW NODE x

Volker.

Re: Decnet traceroute

Sunil Kunnel — Tue, 08 Apr 2008 09:48:12 GMT

for me the next node is the decnet address of CISCO router.I am getting message like unable to connect to listener. I suppose this is because the interface on Router is not configured for listener service.

Thank you.

Re: Decnet traceroute

Volker Halle — Tue, 08 Apr 2008 10:07:26 GMT

Sunil,

not all nodes speaking DECnet protocol are required to implement the NML (NICE or CMIP) protocol.

In case of a CISCO router, you might need to login to that router and find out what commands are available to obtain the desired information.

Volker.

Re: Decnet traceroute

Sunil Kunnel — Tue, 08 Apr 2008 11:07:44 GMT

Thank you , I will have a look.

Re: Decnet traceroute

kari salminen — Wed, 09 Apr 2008 07:12:24 GMT

The old TELL.COM from 80's is here:

http://www.phrack.org/issues.html?issue=27&id=6#article

Re: Decnet traceroute

Paul Beaudoin — Wed, 09 Apr 2008 07:34:12 GMT

Sunil

Here is a procedure written a LONG time ago. As others have pointed out: it will work only when all nodes in the route are Phase IV and answer to NCP TELL commands.
Watch the wrapping
==========================================
$ ! Finds the network path between two nodes
$ ! It does this by NCP TELL commands and displaying the results on the
$ ! users screen. In each case the source node is asked fo the next node
$ ! and circuit to the destination and this is diplayed. The next node then
$ ! becomes the source and the process repeates until the source and
$ ! destination are the same. The destination is then asked for its ID
$ ! string and routing type. This is displayed and the procedure ends.
$ !
$ ! Author: Paul Beaudoin
$ ! Date: AUGUST 13 1988.
$ !
$ ! Files: No files are read or written by this procedure
$ !
$ ! Restrictions:
$ ! This procedure will fail if NML or DECnet account is protected on any
$ ! intervening node.
$ !
$ START:
$ ESCHEX[0,32]=%X1B !Setup escape chart.
$ ESC := 'ESCHEX' !Setup escape symbol1
$ ESCB := "''ESC'[" !Setup escape symbol2
$ WRITE SYS$OUTPUT "''escb'1;3m''escb'2J''escb'3;10H NETWORK PATH"
$ WRITE SYS$OUTPUT "''escb'0;3m
$ E= 0
$ INQ INP "Source Node for this one"
$ IF INP .NES. "" THEN GOTO SOURCE
$ E = 1
$ MC NCP SHO EXEC TO FILE.TMP
$ OPEN/READ INPT FILE.TMP
$ E_READ:
$ READ INPT REC
$ IF F$EXTRACT(0,4,REC) .NES. "Exec" THEN GOTO E_READ
$ CLOSE INPT
$ DEL/NOLOG FILE.TMP;*
$ POS = F$LOCATE("=",REC)
$ LEN = F$LOCATE("(",REC)
$ LEN = LEN-POS
$ TH_NUM = F$EXTRACT('POS+1,'LEN-1,REC)
$ POS = F$LOCATE("(",REC)
$ LEN = F$LOCATE(")",REC)
$ LEN = LEN-POS
$ TH_NAM = F$EXTRACT('POS+1,'LEN-1,REC)
$ GOTO TARGET
$ SOURCE:
$ MC NCP TELL 'INP SHO EXEC TO FILE.TMP
$ IF F$SEARCH("FILE.TMP") .EQS. "" THEN GOTO NO_NODE
$ OPEN/READ INPT FILE.TMP
$ GOTO E_READ
$ TARGET:
$ INQ INP "Target Node"
$ ASS/USER ERR.TMP SYS$ERROR
$ MC NCP TELL 'TH_NUM SHO NODE 'INP TO FILE.TMP
$ IF F$SEARCH("ERR.TMP") .NES. "" THEN GOTO NO_NODE
$ OPEN/READ INPT FILE.TMP
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT " From Via
To"
$ WRITE SYS$OUTPUT ""
$ TG_LOOP:
$ READ INPT REC
$ IF F$LOCATE(")",REC) .EQ. F$LENGTH(REC) THEN GOTO TG_LOOP
$ CLOSE INPT
$ DEL/NOLOG FILE.TMP;*
$ T_NAM = ""
$ POS = F$LOCATE("(",REC)
$ IF POS .LT. 10 THEN GOTO GT_NAM
$ POS = 8
$ T_NAM = "UNKNWN"
$ GT_NAM:
$ T_NUM = F$EXTRACT(0,'POS-1,REC)
$ IF T_NAM .EQS. "UNKNWN" THEN GOTO GET_FIRST
$ LEN = F$LOCATE(")",REC)
$ LEN = LEN - POS
$ T_NAM = F$EXTRACT('POS+1,'LEN-1,REC)
$ GET_FIRST:
$ REC = F$EXTRACT(46,33,REC)
$ POS = F$LOCATE(".",REC)
$ CIRC = F$EXTRACT(0,'POS-3,REC)
$ LEN = F$LOCATE("(",REC)
$ LEN = LEN-POS
$ NX_NUM = F$EXTRACT('POS-2,'LEN+2,REC)
$ NX_NAM = "UNKNWN"
$ IF LEN .GT. 6 THEN GOTO GET_LOOP
$ POS = F$LOCATE("(",REC)
$ LEN = F$LOCATE(")",REC)
$ LEN = LEN-POS
$ NX_NAM = F$EXTRACT('POS+1,'LEN-1,REC)
$ GET_LOOP:
$ PS_NUM[1,7] := 'TH_NUM
$ PS_NAM[1,6] := 'TH_NAM
$ P_CIRC[1,15] := 'CIRC
$ PT_NUM[1,7] := 'NX_NUM
$ PT_NAM[1,6] := 'NX_NAM
$ WRITE SYS$OUTPUT PS_NUM," ",PS_NAM," ==> ",P_CIRC," ==> ",PT_NUM,
" ",PT_NAM
$ IF F$EDIT(NX_NUM,"TRIM") .EQS. F$EDIT(T_NUM,"TRIM") THEN GOTO ENDE
$ TH_NUM = NX_NUM
$ TH_NAM = NX_NAM
$ ASS/USER ERR.TMP SYS$ERROR
$ MC NCP TELL 'NX_NUM SHO NODE 'T_NUM TO FILE.TMP
$ IF F$SEARCH("ERR.TMP") .NES. "" THEN GOTO NO_NODE
$ OPEN/READ INPT FILE.TMP
$ CT = 7
$ N_LOOP:
$ READ INPT REC
$ CT = CT - 1
$ IF CT .GE. 0 THEN GOTO N_LOOP
$ CLOSE INPT
$ DEL/NOLOG FILE.TMP;*
$ REC = F$EXTRACT(46,33,REC)
$ POS = F$LOCATE(".",REC)
$ CIRC = F$EXTRACT(0,'POS-3,REC)
$ LEN = F$LOCATE("(",REC)
$ LEN = LEN-POS
$ NX_NUM = F$EXTRACT('POS-2,'LEN+2,REC)
$ NX_NAM = "UNKNWN"
$ IF LEN .GT. 6 THEN GOTO GET_LOOP
$ POS = F$LOCATE("(",REC)
$ LEN = F$LOCATE(")",REC)
$ LEN = LEN-POS
$ NX_NAM = F$EXTRACT('POS+1,'LEN-1,REC)
$ GOTO GET_LOOP
$ NO_NODE:
$ WRITE SYS$OUTPUT "Next node not responding"
$ IF F$SEARCH("*.TMP") .NES. "" THEN DEL/NOLOG *.TMP;*
$ INQ INP "Press Return to Exit"
$ EXIT
$ ENDE:
$ ASS/USER ERR.TMP SYS$ERROR
$ MC NCP TELL 'T_NUM SHO EXEC CHAR TO FILE.TMP
$ IF F$SEARCH("ERR.TMP") .NES. "" THEN GOTO NO_NODE
$ OPEN/READ INPT FILE.TMP
$ END_LOOP:
$ READ INPT REC
$ IF F$EXTRACT(0,4,REC) .NES. "Iden" THEN GOTO END_LOOP
$ WRITE SYS$OUTPUT T_NUM," ",T_NAM," ",F$EXTRACT(25,40,REC)
$ END_LOOP2:
$ READ INPT REC
$ IF F$EXTRACT(0,4,REC) .NES. "Type" THEN GOTO END_LOOP2
$ WRITE SYS$OUTPUT T_NUM," ",T_NAM," ",F$EXTRACT(25,30,REC)
$ CLOSE INPT
$ DEL/NOLOG *.TMP;*
$ WRITE SYS$OUTPUT ""
$ INQ INP "Press RETURN to exit"
$ EXIT

Re: Decnet traceroute

Sunil Kunnel — Wed, 09 Apr 2008 07:39:36 GMT

Thanks to all for the help.

Re: Decnet traceroute

JohnDite — Fri, 04 Jul 2008 07:37:41 GMT

For a matter of completeness nobody in this thread referred to DECNET_MIGRATE SHOW PATH command. See DECnet Management and/or Problem Solving Guide