topic Lexical functions f$time() in Operating System - OpenVMS

Lexical functions f$time()

geir_2 — Tue, 01 Nov 2005 05:36:07 GMT

Hi,

Is it possible to let f$time write 01, insted of " 1" (leading blank characters)??. I looked at f$cvtime, but could not find any solutions.

I want to include a daynumber in a filename, so blank characters make problems.

Thanks

Re: Lexical functions f$time()

Ian Miller. — Tue, 01 Nov 2005 06:00:44 GMT

It appears that F$TIME, F$CVTIME, F$FAO and so on generate a string with a leading space instead of a 0 eg. 1-NOV-2005.

However you can format this yourself

$ now = F$TIME()
$ d = F$INTEGER(F$CVTIME(now,"ABSOLUTE","DAY"))
$ m = F$CVTIME(now,"ABSOLUTE","MONTH")
$ y = F$CVTIME(now,"ABSOLUTE","YEAR")
$ WRITE SYS$OUTPUT F$FAO("!2ZL-!AS-!AS",d,m,y)

Re: Lexical functions f$time()

David Jones_21 — Tue, 01 Nov 2005 06:10:22 GMT

The comparison output format of f$cvtime() does what you want:
$ day = f$cvtime(f$time(),"COMPARISON","DAY")

Re: Lexical functions f$time()

Hein van den Heuvel — Tue, 01 Nov 2005 08:00:54 GMT

I realize the problem is solved. The comparision time is always my preferred solution as it sorts. but for similar problems elsewhere you may consider the little used/known left assignment in DCL:

$ x = f$time()
$ if f$loc(" ",x).eq.0 then x[0,1]="0"

that is...

If the first found space in X is at offset 0, then make 1 byte at offset 0 be an ascii 0.

fwiw,
Hein.

Re: Lexical functions f$time()

Ian Miller. — Tue, 01 Nov 2005 09:11:11 GMT

$ if f$loc(" ",x).eq.0 then x[0,1]="0"
%DCL-W-IVCHAR, invalid numeric value - check for invalid digits
\0\

replace "0" by ascii code for 0

Re: Lexical functions f$time()

Hein van den Heuvel — Tue, 01 Nov 2005 09:24:43 GMT

Oops, retype error. Thanks for pointing that out Ian.
The line should be:

if f$loc(" ",x).eq.0 then x[0,1]:="0"

I hate re-typing and always cut&paste from working examples, but I was experimenting with a new 'T5515 thin client' at home and could not get the Xterm cut&paste to go. Argh.

The := is a string assignment.
The alternative is just the var[off,len]=val for left bit string assignments.

The suggested solution then becomes:

if f$loc(" ",x).eq.0 then x[0,8]=48

Notice the 8 for 8 bits in a byte.

Hein.

Re: Lexical functions f$time()

Mike Reznak — Tue, 01 Nov 2005 11:18:10 GMT

Hi,

just another way.

$ zz = f$cvtime(,"ABSOLUTE")
$ if f$length(f$ele(0," ",zz)).eq.10 then zz = "0''zz'"

Mike

Re: Lexical functions f$time()

Hein van den Heuvel — Tue, 01 Nov 2005 12:40:39 GMT

Right... f$cvtime(,"absolute") does not have a leading space, where f$time() does.

Instead of the 'heavy' f$elem construction, Mike could also have just tested length:

$ if f$len(zz)).eq.22 then zz = "0" + zz

With the leading space from f$time() you would need:

$ x=f$time()
$ show symb x
X = " 1-NOV-2005 11:31:10.88"
$ if f$extr(0,1,x).eqs." " then x = "0" + f$ext(1,99,x)
$ show symb x
X = "01-NOV-2005 11:31:10.88"
$

I think we now have sufficiently beaten this horse to death :-).

Hein.

Re: Lexical functions f$time()

Ian Miller. — Tue, 01 Nov 2005 12:59:31 GMT

isn't one of the perl mottos - There is always more than one way to do it

:-)

Re: Lexical functions f$time()

Mike Reznak — Wed, 02 Nov 2005 02:28:53 GMT

Hein,
that's even better.
I wasn't shure, if there is 0 preceding morning hours in the string. That's why I've suggested F$ELEMENT.

Mike