Joseph, for what it's worth, I'm running CMS 4.5-2 on 8.3-1H1 bl860's without any problems.
Have you tried switching on all privs and giving it a go. Might help narrow down the problem.
I run this procedure at boot, which may be why I'm not seeing the problems :-
ALPHA_ROB$$ typ CMS$STARTUP_LOCAL.COM
$ ! "CMS$STARTUP_LOCAL.COM"
$!
$!------------------------------------------------------------------------------
$! AUTHOR: ROBERT_ATKINSON - December 2001
$!------------------------------------------------------------------------------
$! DESCRIPTION: Procedure to install CMS images privileges local to TBS, with
$! the correct privileges applied to the images.
$!------------------------------------------------------------------------------
$! RUN FREQUENCY : At system boot/As required
$! PRERUN REQUISITES : None
$! RERUN PROCEDURE : None
$! SPECIAL NOTE :
$!------------------------------------------------------------------------------
$! AMENDMENT LOG:
$! Date Oper Reason
$! 12-11-2002 RAA Added creation of CMS$WEB name table.
$!------------------------------------------------------------------------------
$!
$ SAVE_VERIFY = F$VERIFY(0)
$ !
$START:
$ INSTALL = "$INSTALL /COMMAND_MODE"
$ !
$ ! Add (or replace if it is already installed ("known")) the known images
$ !
$ INSTALL_VERB = "ADD"
$ IF F$FILE("SYS$SHARE:CMSPROSHR.EXE","KNOWN") THEN INSTALL_VERB = "REPLACE"
$ INSTALL 'INSTALL_VERB' SYS$SHARE:CMSPROSHR.EXE /SHARED/PROTECTED/OPEN/PRIV=SYSPRV
$ !
$ INSTALL_VERB = "ADD"
$ IF F$FILE("SYS$SHARE:CMSSHR.EXE","KNOWN") THEN INSTALL_VERB = "REPLACE"
$ INSTALL 'INSTALL_VERB' SYS$SHARE:CMSSHR.EXE /SHARED/OPEN/PRIV=SYSPRV
$ !
$ INSTALL_VERB = "ADD"
$ IF F$FILE("SYS$SYSTEM:CMS.EXE","KNOWN") THEN INSTALL_VERB = "REPLACE"
$ INSTALL 'INSTALL_VERB' SYS$SYSTEM:CMS.EXE /SHARED/OPEN/PRIV=SYSPRV
$ !
$ ! If the CMS$DW.EXE image is available, then it also needs to be installed
$ !
$ IF F$SEARCH("SYS$SYSTEM:CMS$DW.EXE") .EQS. ""
$ THEN
$ ELSE
$ INSTALL_VERB = "ADD"
$ IF F$FILE("SYS$SYSTEM:CMS$DW.EXE","KNOWN") THEN INSTALL_VERB = "REPLACE"
$ INSTALL 'INSTALL_VERB' SYS$SYSTEM:CMS$DW.EXE /SHARED/OPEN/PRIV=SYSPRV
$ ENDIF
$ !
$ INSTALL_VERB = "ADD"
$ IF F$FILE("SYS$SHARE:CMS$EVENT_ACTION.EXE","KNOWN") THEN INSTALL_VERB = "REPLACE"
$ INSTALL 'INSTALL_VERB' SYS$SHARE:CMS$EVENT_ACTION.EXE /SHARED/OPEN/PRIV=SYSPRV
$ !
$ INSTALL_VERB = "ADD"
$ IF F$FILE("SYS$MESSAGE:CMSMSG.EXE","KNOWN") THEN INSTALL_VERB = "REPLACE"
$ INSTALL 'INSTALL_VERB' SYS$MESSAGE:CMSMSG.EXE /SHARED/OPEN/PRIV=SYSPRV
$ !
$ CREATE /NAME_TABLE /PARENT=LNM$SYSTEM_DIRECTORY /PROT=(W:RW) CMS$WEB
$ !
$END:
$ IF SAVE_VERIFY .EQ. 1 THEN SET VERIFY
$ !
$ EXIT %X00001
$ !
$ !
$ !
ALPHA_ROB$$
