Operating System - HP-UX
1745809 Members
3749 Online
108722 Solutions
New Discussion

Re: search the ioscan output?

 
rk_12345
Occasional Contributor

Resize the ioscan output?

Hi All,

 

"ioscan -funC disk" output of our server is huge. We have to sort out few disks along with their HW path and status. Problem is if we grep for disk name, status would not be grep'ed As it is in previous line.

 

Please advice.

 

Thanks..

 

8 REPLIES 8
James R. Ferguson
Acclaimed Contributor

Re: Resize the ioscan output?

Hi:

 

And so the question really becomes one of how to match a token and show the previous line of the match, too.  You asked that as a *generalization* in your other thread today, and you will find suggestions there:

 

http://h30499.www3.hp.com/t5/Languages-and-Scripting/Search-for-an-expression-and-capture-few-lines-above-amp-below/m-p/5350803#M42376

 

Regards!

 

...JRF...

Dennis Handly
Acclaimed Contributor

Re: search the ioscan output?

>Problem is if we grep for disk name, status would not be grep'ed As it is in previous line.

 

You could use sed to find the first line then join the next and then if it matches print it.

rk_12345
Occasional Contributor

Re: search the ioscan output?

As per James, I have installed GNU grep and that works well. But the problem is I cannot do this on all the hosts...can you please let me know how do we use sed for the same like "grep -A1 B1".
Pete Randall
Outstanding Contributor

Re: search the ioscan output?

Handy one-liners for SED

HANDY ONE-LINERS FOR SED (Unix stream editor)              April 25, 1998
compiled by Eric Pement <epement@jpusa.chi.il.us>             version 4.5
Latest version of this file is always at <http://www.wollery.demon.co.uk>

FILE SPACING:

 # double space a file
 sed G

 # triple space a file
 sed 'G;G'

 # undo double-spacing (assumes even-numbered lines are always blank)
 sed 'n;d'

NUMBERING:

 # number each line of a file (simple left alignment). Using a tab (see
 # note on '\t' at end of file) instead of space will preserve margins.
 sed = filename | sed 'N;s/\n/\t/'

 # number each line of a file (number on left, right-aligned)
 sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'

 # number each line of file, but only print numbers if line is not blank
 sed '/./=' filename | sed '/./N; s/\n/ /'

 # count lines (emulates "wc -l")
 sed -n '$='

TEXT CONVERSION AND SUBSTITUTION:

 # IN UNIX ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format
 sed 's/.$//'               # assumes that all lines end with CR/LF
 sed 's/^M$//'              # in bash/tcsh, press Ctrl-V then Ctrl-M
 sed 's/\x0D$//'            # sed v1.5 only

 # IN DOS ENVIRONMENT: convert Unix newlines (LF) to DOS format
 sed 's/$//'                          # method 1
 sed -n p                             # method 2

 # delete leading whitespace (spaces, tabs) from front of each line
 # aligns all text flush left
 sed 's/^[ \t]*//'                    # '\t'=tab (see note at end of file)

 # delete trailing whitespace (spaces, tabs) from end of each line
 sed 's/[ \t]*$//'                    # '\t'=tab (see note at end of file)

 # delete BOTH leading and trailing whitespace from each line
 sed 's/^[ \t]*//;s/[ \t]*$//'

 # insert 5 blank spaces at beginning of each line (make page offset)
 sed 's/^/     /'

 # align all text flush right on a 79-column width
 sed -e :a -e 's/^.\{1,78\}$/ &/;ta'  # set at 78 plus 1 space

 # center all text in the middle of 79-column width. In method 1,
 # spaces at the beginning of the line are significant, and trailing
 # spaces are appended at the end of the line. In method 2, spaces at
 # the beginning of the line are discarded in centering the line, and
 # no trailing spaces appear at the end of lines.
 sed  -e :a -e 's/^.\{1,77\}$/ & /;ta'                     # method 1
 sed  -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/'  # method 2

 # substitute (find & replace) "foo" with "bar" on each line
 sed 's/foo/bar/'             # replaces only 1st instance in a line
 sed 's/foo/bar/4'            # replaces only 4th instance in a line
 sed 's/foo/bar/g'            # replaces ALL instances in a line

 # substitute "foo" with "bar" ONLY for lines which contain "baz"
 sed '/baz/s/foo/bar/g'

 # substitute "foo" with "bar" EXCEPT for lines which contain "baz"
 sed '/baz/!s/foo/bar/g'

 # reverse order of lines (emulates "tac")
 sed '1!G;h;$!d'

 # reverse each character on the line (emulates "rev")
 sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'

 # join pairs of lines side-by-side (like "paste")
 sed 'N;s/\n/ /'

SELECTIVE PRINTING OF CERTAIN LINES:

 # print all but first line of file
 sed 1d infile >> outfile

 # print first 10 lines of file (emulates behavior of "head")
 sed 10q

 # print first line of file (emulates "head -1")
 sed q

 # print last 10 lines of file (emulates "tail")
 sed -e :a -e '$q;N;11,$D;ba'

 # print last line of file (emulates "tail -1")
 sed '$!d'

 # print only lines which match regular expression (emulates "grep")
 sed -n '/regexp/p'           # method 1
 sed '/regexp/!d'             # method 2

 # print only lines which do NOT match regexp (emulates "grep -v")
 sed -n '/regexp/!p'          # method 1, corresponds to above
 sed '/regexp/d'              # method 2, simpler syntax

 # print 1 line of context before regexp
 sed -n -e '/regexp/{x;1!p;g;p;}' -e h 

 # print 1 line of context before and after regexp, with line number
 # indicating where the regexp occurred (similar to "grep -A1 -B1")
 sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h

 # grep for AAA and BBB and CCC (in any order)
 sed '/AAA/!d; /BBB/!d; /CCC/!d'

 # grep for AAA and BBB and CCC (in that order)
 sed '/AAA.*BBB.*CCC/!d'

 # grep for AAA or BBB or CCC (emulates "egrep")
 sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d

 # print paragraph if it contains AAA (blank lines separate paragraphs)
 # HHsed v1.5 must insert a 'G;' after 'x;' in the next 3 scripts below
 sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'

 # print paragraph if it contains AAA and BBB and CCC (in any order)
 sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'

 # print paragraph if it contains AAA or BBB or CCC
 sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d

 # print only lines of 65 characters or longer
 sed -n '/^.\{65\}/p'

 # print only lines of less than 65 characters
 sed -n '/^.\{65\}/!p'        # method 1, corresponds to above
 sed '/^.\{65\}/d'            # method 2, simpler syntax

 # print section of file from regular expression to end of file
 sed -n '/regexp/,$p'

 # print section of file based on line numbers (lines 8-12, inclusive)
 sed -n '8,12p'               # method 1
 sed '8,12!d'                 # method 2

 # print line number 52
 sed -n '52p'                 # method 1
 sed '52!d'                   # method 2
 sed '52q;d'                  # method 3, efficient on large files

 # print section of file between two regular expressions (inclusive)
 sed -n '/Iowa/,/Montana/p'             # case sensitive

SELECTIVE DELETION OF CERTAIN LINES:

 # print all of file EXCEPT section between 2 regular expressions
 sed '/Iowa/,/Montana/d'

 # delete duplicate lines from a sorted file (emulates "uniq"). First
 # line in a set of duplicate lines is kept, the rest are deleted
 sed '$!N; /^\(.*\)\n\1$/!P; D'

 # delete ALL blank lines from a file (same as "grep '.' ")
 sed '/^$/d'

 # delete all CONSECUTIVE blank lines from file except the first; also
 # deletes all blank lines from top and end of file (emulates "cat -s")
 sed '/./,/^$/!d'          # method 1, allows 0 blanks at top, 1 at EOF
 sed '/^$/N;/\n$/D'        # method 2, allows 1 blank at top, 0 at EOF

 # delete all CONSECUTIVE blank lines from file except the first 2:
 sed '/^$/N;/\n$/N;//D'

 # delete all leading blank lines at top of file
 sed '/./,$!d'

 # delete all trailing blank lines at end of file
 sed -e :a -e '/^\n*$/N;/\n$/ba'

 # delete the last line of the file
 sed -e '$d' outputfile

 # delete the last line of each paragraph
 sed -n '/^$/{p;h;};/./{x;/./p;}'

SPECIAL APPLICATIONS:

 # remove nroff overstrikes (char, backspace) from man pages. The 'echo'
 # command may need an -e switch if you use Unix System V or bash shell.
 sed "s/.`echo \\\b`//g"    # double quotes required for Unix environment
 sed 's/.^H//g'             # in bash/tcsh, press Ctrl-V and then Ctrl-H
 sed 's/.\x08//g'           # hex expression for sed v1.5

 # get Usenet/e-mail message header
 sed '/^$/q'                # deletes everything after first blank line

 # get Usenet/e-mail message body
 sed '1,/^$/d'              # deletes everything up to first blank line

 # get Subject header, but remove initial "Subject: " portion
 sed '/^Subject: */!d; s///;q'

 # get return address header
 sed '/^Reply-To:/q; /^From:/h; /./d;g;q'

 # parse out the address proper. Pulls out the e-mail address by itself
 # from the 1-line return address header (see preceding script)
 sed 's/ *(.*)//; s/>.*//; s/.*[:<] *//'

 # add a leading angle bracket and space to each line (quote a message)
 sed 's/^/> /'

 # delete leading angle bracket & space from each line (unquote a message)
 sed 's/^> //'

 # remove most HTML tags (accommodates multiple-line tags)
 sed -e :a -e 's/<[^>]*>//g;/</N;//ba'

 # extract multi-part uuencoded binaries, removing extraneous header
 # info, so that only the uuencoded portion remains. Files passed to
 # sed must be passed in the proper order. Version 1 can be entered
 # from the command line; version 2 can be made into an executable
 # Unix shell script. (Modified from a script by Rahul Dhesi.)
 sed '/^end/,/^begin/d' file1 file2 ... fileX | uudecode   # vers. 1
 sed '/^end/,/^begin/d' $* | uudecode                      # vers. 2

 # zip up each .TXT file individually, deleting the source file and
 # setting the name of each .ZIP file to the basename of the .TXT file
 # (under DOS: the "dir /b" switch returns bare filenames in all caps).
 echo @echo off >zipup.bat
 dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat

TYPICAL USE: Sed takes one or more editing commands and applies all of
them, in sequence, to each line of input. After all the commands have
been applied to the first input line, that line is output and a second
input line is taken for processing, and the cycle repeats. The
preceding examples assume that input comes from the standard input
device (i.e, the console, normally this will be piped input). One or
more filenames can be appended to the command line if the input does
not come from stdin. Output is sent to stdout (the screen). Thus:

 cat filename | sed '10q'        # uses piped input
 sed '10q' filename              # same effect, avoids a useless "cat"
 sed '10q' filename > newfile    # redirects output to disk

For additional syntax instructions, including the way to apply editing
commands from a disk file instead of the command line, consult "sed &
awk, 2nd Edition," by Dale Dougherty and Arnold Robbins (O'Reilly,
1997; http://www.ora.com), "UNIX Text Processing," by Dale Dougherty
and Tim O'Reilly (Hayden Books, 1987) or the tutorials by Mike Arst
distributed in U-SEDIT2.ZIP (many sites). To fully exploit the power
of sed, one must understand "regular expressions." For this, see
"Mastering Regular Expressions" by Jeffrey Friedl (O'Reilly, 1997).
The manual ("man") pages on Unix systems may be helpful (try "man
sed", "man regexp", or the subsection on regular expressions in "man
ed"), but man pages are notoriously difficult. They are not written to
teach sed use or regexps to first-time users, but as a reference text
for those already acquainted with these tools.

QUOTING SYNTAX: The preceding examples use single quotes ('...')
instead of double quotes ("...") to enclose editing commands, since
sed is typically used on a Unix platform. Single quotes prevent the
Unix shell from intrepreting the dollar sign ($) and backquotes
(`...`), which are expanded by the shell if they are enclosed in
double quotes. Users of the "csh" shell and derivatives will also need
to quote the exclamation mark (!) with the backslash (i.e., \!) to
properly run the examples listed above, even within single quotes.
Versions of sed written for DOS invariably require double quotes
("...") instead of single quotes to enclose editing commands.

USE OF '\t' IN SED SCRIPTS: For clarity in documentation, we have used
the expression '\t' to indicate a tab character (0x09) in the scripts.
However, most versions of sed do not recognize the '\t' abbreviation,
so when typing these scripts from the command line, you should press
the TAB key instead. '\t' is supported as a regular expression
metacharacter in awk, perl, and in a few implementations of sed.

VERSIONS OF SED: Versions of sed do differ, and some slight syntax
variation is to be expected. In particular, most do not support the
use of labels (:name) or branch instructions (b,t) within editing
commands, except at the end of those commands. We have used the syntax
which will be portable to most users of sed, even though the popular
GNU versions of sed allow a more succinct syntax. When the reader sees
a fairly long command such as this:

   sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d

it is heartening to know that GNU sed will let you reduce it to:

   sed '/AAA/b;/BBB/b;/CCC/b;d'

In addition, remember that while many versions of sed accept a command
like "/one/ s/RE1/RE2/", some do NOT allow "/one/! s/RE1/RE2/", which
contains space before the 's'. Omit the space when typing the command.

OPTIMIZING FOR SPEED: If execution speed needs to be increased (due to
large input files or slow processors or hard disks), substitution will
be executed more quickly if the "find" expression is specified before
giving the "s/.../.../" instruction. Thus:

   sed 's/foo/bar/g' filename         # standard replace command
   sed '/foo/ s/foo/bar/g' filename   # executes more quickly
   sed '/foo/ s//bar/g' filename      # shorthand sed syntax

On line selection or deletion in which you only need to output lines
from the first part of the file, a "quit" command (q) in the script
will drastically reduce processing time for large files. Thus:

   sed -n '45,50p' filename           # print line nos. 45-50 of a file
   sed -n '51q;45,50p' filename       # same, but executes much faster


Pete
James R. Ferguson
Acclaimed Contributor

Re: search the ioscan output?

Hi (again):

 

Here's a simple Perl script that should meet your needs:

 

#!/usr/bin/perl
use strict;
use warnings;
my $pattern = shift or die "pattern expected\n";
my ( $seen, $before );
while (<>) {
    if (m{$pattern}) {
        print $before if defined $before;
        print;
        $before = undef;
        $seen   = $.;
        next;
    }
    if ($seen) {
        $seen = 0;
        print;
        next;
    }
    $before = $_;
}
1;

Run like this:

 

# ./myfilter token file

 

For example to match "local' in /etc/hosts, do:

 

# ./myfilter local /etc/hosts

 

Regards!

 

...JRF...

Bill Hassell
Honored Contributor

Re: search the ioscan output?

Here is a one-liner using awk:

 

  MYDISK=c9t12d0
ioscan -knfCdisk| awk "/$MYDISK/"'{print x;print}{x=$0}'

 

This will find the device filename ($MYDISK) and print the previous line and device file line.

 

You can also get hardware path information on one line with lssf:

 

lssf /dev/dsk/c9t12d0

 

 



Bill Hassell, sysadmin
Dennis Handly
Acclaimed Contributor

Re: search the ioscan output?

>You could use sed to find the first line then join the next and then if it matches print it.

 

If you have pairs of sequential lines where the first has a token and the second another and you only want to print the two if they have those two tokens:

sed -n -e '
/FIRST/ h  # first line
/FOUND/ {  # second line
   H       # append to hold
   g       # replace by hold
   /FIRST.*\n.*FOUND/ p  # print only if both tokens
}' file

Bill Hassell
Honored Contributor

Re: Resize the ioscan output?

Another solution:

 

Since you know the disk you want the details for, use this technique:

 

# lssf /dev/dsk/c8t7d0
sdisk card instance 8 SCSI target 7 SCSI LUN 0 section 0 at address 0/3/0/0.8.0.255.0.7.0 /dev/dsk/c8t7d0

# lssf /dev/dsk/c8t7d0 | awk '{print $15}'
0/3/0/0.8.0.255.0.7.0

# MYDISK=/dev/dsk/c8t7d0
# ioscan -kfH $(lssf $MYDISK | awk '{print $15}'
Class     I  H/W Path     Driver S/W State   H/W Type     Description
======================================================================
disk     42  0/3/0/0.8.0.255.0.7.0  sdisk  CLAIMED     DEVICE       HP 73.4GST373405FC

Notice the use of -k in ioscan. It returns instantly. Without -k, ioscan must search every I/O card and every device. On a big system, ioscan -k is 20-100 times faster.

Now, for scripting, you might want to use the -F option so every field has a delimiter:

# MYDISK=/dev/dsk/c8t7d0
# ioscan -kFH $(lssf $MYDISK | awk '{print $15}'
scsi:wsio:T:T:F:31:188:552960:disk:sdisk:0/3/0/0.8.0.255.0.7.0:0 0 3 18 0 0 0 0 65 173 116 171 34 102 253 110 :42:root.sba.lba.td.fcp.fcpdev.tgt.sdisk:sdisk:CLAIMED:DEVICE:HP 73.4GST373405FC:8
 
In this case, there is no header to skip and fields with spaces can be easily extracted:

# ioscan -kFH $(lssf $MYDISK | awk '{print $15}') | awk -F: '{print $(NF-3),$(NF-1)}'
CLAIMED HP 73.4GST373405FC

Now the CLAIMED status and the product (SCSI-ID) description are extracted directly with a one liner. See man ioscan for details about the fields.


Bill Hassell, sysadmin