Can I delete the contents of old PCSI$UNDO directories?

[Dennis D Hagen]

Old PCSI$UNDO directories are beginning to take too much space on my system disk.(Currently I have directories named from PCSI$UNDO_001... to PCSI$UNDO_030...)

Can any of these be safely deleted or moved to a non-system disk?

[Steven Schweda]

There are probably some more details, but
you may wish to leave the directories in
place. If you [re]move them, I believe that
the installer will start over at "_001" the
next time, and I assume that this will
confuse (if not confound) any later attempts
to use the things. (I have no idea if the
"_xxx" values are remembered anywhere, or if
scrambling them would really be harmless.)

If you don't expect to use them for a long
time, I believe that it's pretty safe to
Zip the contents. As I recall, you can save
a lot of space that way. The important thing
is to leave the directory there to keep the
numbers straight, so it's probably safer to
SET DEFAULT into each one and Zip
"[...]*.*;*", rather than to start in
SYS$SYSDEVICE:[000000] and Zip
"[PCSI_UNDO_xxx...]*.*;*" (and then throw
the whole directory away). Then you can
DELETE SYS$SYSDEVICE:[PCSI_UNDO_*...]*.*;* /EXCLUDE = *.ZIP

My warranty-free procedure looks like this:

alp $ type sys$manager:ZIP_UNDO.COM
$! 5 February 2006. SMS.
$!
$! Zip-compress SYS$SYSDEVICE:[PCSI_UNDO_*] directories.
$!
$! When satisfied, repeat until complete:
$! DELETE SYS$SYSDEVICE:[PCSI_UNDO_*...]*.*;* /EXCLUDE = *.ZIP
$!
$ zip_temp_file_name = "ZI*."
$!
$! Save process state data.
$!
$ def_dev_dir_orig = f$environment( "DEFAULT")
$ proc_parse_orig = f$getjpi( "", "PARSE_STYLE_PERM")
$!
$ on error then goto clean_up
$ on control_y then goto clean_up
$!
$ set process /parse_style = extended
$!
$ set default sys$sysdevice:[000000]
$!
$ loop:
$ dir = f$search( "PCSI$UNDO_*.DIR;1", 1)
$ if (dir .nes. "")
$ then
$ name = f$parse( dir, , , "NAME", "SYNTAX_ONLY")
$ set default sys$sysdevice:['name']
$ write sys$output " Directory: [''name']"
$!
$ temp_name = f$search( zip_temp_file_name)
$ if (temp_name .nes. "")
$ then
$ write sys$output " --- Possible Zip temp file exists: ---"
$ loop_temp:
$ write sys$output " ''temp_name'"
$ temp_name = f$search( zip_temp_file_name)
$ if (temp_name .nes. "") then goto loop_temp
$ endif
$!
$ if (f$search( "''name'.zip") .eqs. "")
$ then
$ zip -V -w -9 'name'.zip [...]*.*;*
$ else
$ write sys$output " *** ""[''name']''name'.zip"" exists. ***"
$ endif
$!
$ goto loop
$ endif
$!
$! Restore process state data.
$!
$ clean_up:
$!
$ set default 'def_dev_dir_orig'
$ set process /parse_style = 'proc_parse_orig'
$!

Of course, if it's safe to wreck the
directory contents, it should be safe to move
them to another disk, but I would still leave
all the original directories in place, for
the reason given.

And, yes, I know that there are more clever
ways to do the DELETE operation.

[Dennis D Hagen]

Thanks for the tips on zipping/backingup the PCSI$UNDO files.

I'd still like to know whether I can delete or move some of them. If the "undo number" in the directory names means that 1 is most recent and 30 (in my case) is oldest, then I'd like to delete or move something like 15-30.

[Andy Bustamante · Accepted solution]

You can use PCSI for clean up.

$ PRODUCT DELETE RECOVERY_DATA

Some options are
/ALL
/BEFORE
/OLDEST=x

See http://h71000.www7.hp.com/doc/732FINAL/6048/6048pro_004.html#startsubcommand_318 for more information. As a rule, I qualify batches in bundles and delete the old bundle recovery data before installing a new bundle. Offically the target is once a quarter so there's time to nice any issues.


Andy

[Jiri_5]

If you make backup before new instalation you can delete PCSI$UNDO... before new instalation (PRODUCT DELETE RECOVERY_DATA). That directore are created when you install with parametr /save_recovery_data.

[John Abbott_2]

You can use the

$ PRODUCT SHOW RECOVERY_DATA

To view these directories and to see what the product tool makes of them. Gives creation date, patch info. There are a few qualifiers available too.

J.

[Volker Halle]

Dennis,

the PRODUCT UNDO PATCH feature is meant as a supported method for easily removing the most recently installed patch(es), if a problem has been detected (soon) after installing those patches.

Before this feature became available, you would have to restore your system backup taken before the patch installation.

You can only UNDO patches in the reverse order of installation, so keeping 30 recovery data sets stored on the system disk for an extended period of time may not make too much sense. You would have to UNDO all 30 patches, if you suspected a problem with the first patch installed.

If you need to install a product .PCSI kit (with PRODUCT INSTALL), all recovery data sets would have to be deleted anyway.

Volker.

[Dennis D Hagen]

Thanks to Andy Bustamonte for the definitive answer!