Empty out a VMS print queue

[Jorge Cocomess]

Greetings,

Is there a easier way to empty out a VMS queue with one (1) command line? I have hundreds of entries in this queue and it would take a good 1 hour to empty it by a simgle del/entry=xxx

Please help.

Thank you in advance.
Jorge

[Volker Halle · Accepted solution]

Jorge,

note the queue configuration (SHO QUE/FULL) and delete the queue with: DELETE/QUEUE queue-name. Then re-create the queue with the previously documented settings.

Volker.

[Jorge Cocomess]

I get an error deleting the queue. And yes, I did stopped the queue prior deleting it.

[Karl Rohwedder]

Jorgem
did you do a STOP/QUE/NEXT? perhaps this is an execution queue with a generic queue pointing to it? Then you have to stop/delete the generic queue 1st.

regards Kalle

[Jefferson Humber]

Hi Jorge,

I had a little .COM file once that did what you are after, since I couldn't find a way to do it from a single command.

I think it worked with a bit of F$GETQUI in a loop.

I'll have a hunt around and see if I can find it, can't promise it's still about though it was a few years ago.

Jeff

[Jefferson Humber]

Can't find my version, but there is one here on comp.os.vms

http://groups.google.co.uk/group/comp.os.vms/browse_frm/thread/85cdd2ec23acad70/0ace51f857bfc431?lnk=st&q=delete+print+queue+entries+vms&rnum=11&hl=en#0ace51f857bfc431

Jeff

[Jorge Cocomess]

Jeff - Works like a charm in 7.3-2

~Many thanks!!

J

[Gregg Parmentier]

I think this one is a bit more efficient than the one at the search link, since it doesn't have to loop to find the correct print queue. If you have lots of queues, this might make a noticable difference.

It also checks only printer and terminal queues so you can't acidentally clean out an execution queue with a typo. The I/O syntax might not be as clean, though:-)

$ If (P1.NES."")
$ THEN
$ WHICH_Q = P1
$ ELSE
$ READ/END=DONE/PROMPT="Enter the name of the queue you wish to clean: " -
SYS$COMMAND WHICH_Q
$ IF WHICH_Q .EQS. "" THEN GOTO DONE
$ ENDIF
$
$! check queue existence and set context
$ Q_NAME = F$GETQUI("DISPLAY_QUEUE","QUEUE_NAME","''which_q'","PRINTER,TERMINAL,WILDCARD")
$ IF Q_NAME .EQS. "" THEN GOTO NO_QUEUE
$ STOP/QUEUE/RESET 'Q_NAME'
$
$LOOP:
$! get the next entry number and delete it from the queue
$ ENTRY == F$GETQUI("DISPLAY_JOB","ENTRY_NUMBER",,"ALL_JOBS,WILDCARD")
$ IF (ENTRY.EQS."") THEN GOTO DONE
$ DELETE/ENTRY='ENTRY' 'Q_NAME'
$ GOTO LOOP
$
$NO_QUEUE:
$ WRITE SYS$OUTPUT "Queue ''which_q' does not exist."
$
$DONE:
$! clear queue context
$ Q_NAME = F$GETQUI("")

[Jess Goodman]

The easiest way to empty out a batch or print queue takes 3 lines of DCL:

$ INIT /QUEUE JUNKQ !add /BATCH or /DEVICE
$ ASSIGN/MERGE JUNKQ the_real_q
$ DELETE/QUEUE JUNKQ

[Karl Rohwedder]

Attached is a small procedure, that moves queue entries to/from a 'dummy' queue, in order to allow maintenance on the original queue.

regards Kalle

[Wim Van den Wyngaert]

I like the solution of Jess. Didn't think of it (esp. when you are without your toolkit).

Wim

[Galen Tackett]

In 20+ years with VMS I don't recall coming across Jess's solution ever before (but my memory is pretty bad these days.) It is efficient, clever, and elegant (in a sort of mathematical sense.)

[Joseph Huber_1]

My solution, which lets select jobs by user,by name, or by queue name:

http://wwwvms.mppmu.mpg.de/util_root/com/abojob.com