fwiw,
If I were to use DCL to code something like the more extensive attachment provided, then I would code it rather differently.
I'd highlight the search targets early on, in the expected order.
Two examples in slight different styles below. Specifically first one will we a very tight loop through the file.
I used numeric labels, but it is easy enough to make them text using something like:
$labels = "|main|proc|bal|non|bus|paged|lock"
:
$label = f$elem(target,"|",labels)
$goto do_23_'label'
fwiw,
Hein.
$ targets = -
"1234567890123| Main Memory| Process Ent| Balance Set|"+-
" Nonpaged Dy| Bus Address| Paged Dynam| Lock Manage|"
$ not_seen = "1 2 3 4 5 6 7 "
$ lt=f$len(targets)
$ close/nolog x
$ open/read x tmp.tmp
$r23:
$ read/end=e23 x x_rcd
$ target = f$loc(f$extr(0,13,x_rcd), targets)
$ if target.eq.lt then goto r23
$ target = target/14
$ not_seen = not_seen - "''target' "
$ goto d_23_'target
$
$d_23_0:
$d_23_1:
$d_23_2:
$d_23_3:
$d_23_4:
$d_23_5:
$d_23_6:
$d_23_7:
$d_23_8:
$d_23_9:
$write sys$output x_rcd
$goto r23
$e23:
$if not_seen.nes."" then write sys$output "did not find: ", -
not_seen, f$elem(f$elem(0," ",not_seen),"|",targets)
$exit
or...
$ targets="|Process Entry Slots|Balance Set Slots|"+-
"Paged Dynamic Memory|Nonpaged Dynamic Memory|"+-
"Bus Addressable Memory|Lock Manager Dynamic Memory|"+-
"Lock Manager Dyn Memory|Main Memory"
$ open/read x tmp.tmp
$r23:
$ read/end=e23 x x_rcd
$ li=f$len(x_rcd)
$ target = 0
$i23:
$ target = target + 1
$ it = f$element(target,"|",targets)
$ if it.eqs."|" then goto r23
$ pos=f$loc(it,x_rcd)
$ if pos .eq. li then goto i23
$ targets = targets - "|''it'"
$ goto d_23_'target
$
$d_23_0:
$d_23_1:
$d_23_2:
$d_23_3:
$d_23_4:
$d_23_5:
$d_23_6:
$d_23_7:
$d_23_8:
$d_23_9:
$write sys$output x_rcd
$goto r23
$e23:
$if targets.nes."" then write sys$output "did not find: ", targets
$exit
