trying to inventory old apps still running on our vax cluster

[Gary Donatelli]

Is there a way to see which applications we are still running on our Vax/Vms cluster? We are running vms6.2. We have had many applications run on this cluster over the years and we want to see what is actually still on it and running?

[Andy Bustamante]

Looking at layered products would miss any internal customer code that may have been written. If I were approaching the project, I'd start with user interviews. What applications do you still use. What information needs to be available even if you don't use it every day?

Andy

[Jim_McKinney]

Regarding the "running" portion of your task - you might just try enabling image accounting. You might try variations of the following commands (HELP can provide further details):

$ set acco/enab=imag

$ acco/summ=imag

Note that the amount of disk space consumed by ACCOUNTNG.DAT will depend upon how many image activations occur on your systems.

[Hein van den Heuvel]

Here is an other thought...
A simple DCL script which look around (world priv needed!) and counts images as it sees them being used, remembering the last user and last usage time.
Submit to run every 30 minutes or so.
Let it run for a week.

Now check the file it created with: Name, Count, Time, User.

Sample output and script below.

$ type images.tmp ! Sample output
Image Count Procedure 7 2007-01-08 16:54 HEIN
MAIL 5 2007-01-08 16:54 HEIN
PHONE 8 2007-01-08 16:54 HEIN
TPU 3 2007-01-08 16:54 HEIN


$ type images.com ! Script
$!
$! images.com, Jan-2007 Hein van den Heuvel
$! Take a peek at the system to see who is using what images.
$! Remember and count usage in an indexed file
$! Record: image-name(25), usage-count(10), last-time(16), last-user(12)
$!
$ if "".eqs.f$trnlnm("image_file") then def/job image_file SYS$LOGIN:images.TMP
$ if "".eqs.f$search("image_file") then gosub create_image_file
$ now = F$EXTR(0,16,F$CVTIME())
$ open/read/write images image_file
$ context = ""
$ last_pid = ""
$ pid = F$PID(context) ! picks up ourself, no image, for initial record update
$loop:
$ verify_pid := 'pid
$ user = F$FAO("!12AS", F$GETJPI(pid,"USERNAME"))
$ image = F$FAO("!25AS", F$PARSE(F$GETJPI(pid,"IMAGNAME"),,,"NAME"))
$ read/key=ℑ/error=not_found_we_suspect images record
$ usage = 'f$extract(25,10,record)
$ usage = usage + 1
$ write/update images f$fao("!25AS!10UL !16AS !12AS", image, usage, now, user)
$ pid = F$PID(context)
$ if pid.nes."" then goto loop
$ status = 1
$done:
$ close images
$ exit 'status
$
$not_found_we_suspect:
$ status = $STATUS
$ if pid.eqs.last_pid then goto done
$ last_pid = pid ! Do not loop
$ write images f$fao("!25AS!10UL", image, 0)
$ goto loop ! try again
$
$create_image_file:
$ create/fdl=sys$input/log image_file
FILE
ORGANIZATION indexed
KEY 0
SEG0_LENGTH 25
SEG0_POSITION 0
$ return

[Paul Beaudoin]

Good one Hein ... This (I assume) will give a list of images accessed over time. Now to translate those images back to products is the challenge. I have a number of old (probably suitable for VMS 6.x) listings that can be used to translate image names to (Digital) products if any use. I think they came from Propatch or similar processes used to document systems. Alternatively, there was a product called PRODUCT on early Freeware disks that claimed to do similar things. Not tried myself but a quick search and scan of the doc might be useful. If you want the xlate listings, please mail me.

Regards (and good luck)

Paul