John,
>I've read some people say just to delete
>those files in the sys$specific.
Probably better to move them into SYS$COMMON. The trick then, as others have said, is to always refer to the files by their cluster common name when editing. I have a sanity check procedure that looks for files in the common root which may be obscured.
As you've learned, files in a SYS$SPECIFIC root will mask one in SYS$COMMON. If you find some circumstance where it makes sense to have a separate SYS$SPECIFIC file, you can explicitly execute the SYS$COMMON version from it. For example, suppose we want to startup APACHE on just one node. I'm assuming that the TCPIP startup will be in the common startup, so we want to start APACHE after the common has completed.
SYS$SPECIFIC:[SYSMGR]STARTUP_VMS.COM
$ SET NOON ! Continue regardless of errors
$ node=F$GETSYI("NODENAME")
$ self=F$PARSE(";",F$ENVIRONMENT("PROCEDURE"))
$ WRITE SYS$OUTPUT "Executing node specific startup for ''node' at ''F$TIME()' ''self'"
$
$ ! Do stuff which needs to be done before the common startup here
$
$ common= F$PARSE("SYS$COMMON",self)
$ IF F$SEARCH(common).NES."" THEN @'common'
$
$ ! Do stuff which needs to wait until the common startup is complete here
$
$ apache="SYS$STARTUP:APACHE$STARTUP.COM"
$ IF F$SEARCH(apache).NES."" THEN @'apache'
$
$ WRITE SYS$OUTPUT "Node specific startup completed for ''node' at ''F$TIME()'"
$ EXIT
Common startup looks like this:
SYS$COMMON:[SYSMGR]SYSTARTUP_VMS.COM
$ SET NOON ! Continue regardless of errors
$ node=F$GETSYI("NODENAME")
$ self=F$PARSE(";",F$ENVIRONMENT("PROCEDURE"))
$ WRITE SYS$OUTPUT "Executing cluster common startup for ''node' at ''F$TIME()' ''self'"
$
$ ! Do startups
$
$ WRITE SYS$OUTPUT "Cluster common startup completed for ''node' at ''F$TIME()' ''self'"
$ EXIT
This is just one way to configure your cluster. In practice, it's better that all nodes in the cluster run the same software, so the startup procedure is identical for all nodes, and kept in SYS$COMMON. Having common code wherever possible means there's less chance for inconsistencies.
(I also have a policy of never hardcoding anything which can be determined easily. For example, finding the executing procedure name with F$ENVIRONMENT("PROCEDURE"), rather than coding it as "SYSTARTUP_VMS" means that identical code can be used in any of the SYS$STARTUP procedures).
A crucible of informative mistakes
