Wim
Is this what you had in mind (My applogies to the original author - I can't remember where I got this)
Watch for wrapping
Paul
DCL_NUMBERING.COM
$! Run this proc against DCL source
$! 2. output will be named proc.post_com
$! 3. execute proc.post_com instead of source
$! 4. source line nr will be recorded in local symbol "L" for each DCL line
$! interpreted
$! 5. write error handler to display/print last line number when triggered.
$ v=f$v(0)
$ on warning then exit
$ if p1 .eqs. "" then inq p1 "Input file"
$ if p1 .eqs. "" then exit
$ if f$search(p1) .eqs. ""
$ then
$ write sys$output p1," not found"
$ exit
$ endif
$ out_file = f$parse(p1,,,"name") + ".POST_COM"
$ write sys$output "Resulting file is ",f$dir(),out_file
$ close/nolog ch
$ close/nolog ch2
$ open/read ch 'p1'
$ open/write ch2 'out_file'
$ i=0
$ skip="NO"
$LOOP:
$ read/end=EOF ch line
$ write ch2 line
$ i=i+1
$ rec = "$L=''i'"
$! what are the lines that we don't want to mess up
$ line2=f$edit(line,"UPCASE,COLLAPSE")
$ if f$extract(0,3,line2) .eqs. "$!#" .or. - !metadata
f$extract(0,4,line2) .eqs. "$SQL" .or. - !interactive
f$extract(0,5,line2) .eqs. "$DECK" .or. - !(obvious?)
f$extract(0,7,line2) .eqs. "$CREATE" .and. - !idem $DECK
f$extract(7,1,line2) .nes. "/" then skip = "YES" !others are good
$!
$ if f$extract(0,8,line2) .eqs. "$CREATE=" then skip = "NO" !assignment
$!
$ if f$extract(0,3,line2) .eqs. "$!&" .or. - !metadata
f$extract(0,4,line2) .eqs. "$EOD" then skip = "NO" !end of $DECK
$!
$ if f$extract(0,2,line2) .nes. "$!"
$ then
$ line2=f$edit(line,"COLLAPSE,UNCOMMENT")
$ if f$extract(f$len(line2)-1,1,line2) .nes. "-" !don't mess it..
$ then !..if cont line
$ if skip .eqs. "NO" then write ch2 rec !write line nr
$ i=i+1 !inc line nr
$ endif
$ endif
$ goto LOOP
$EOF:
$ close ch
$ close ch2
$ v=f$v(v)
$ write sys$output "Done"
$ exit
