Oracle RDB Install on Itanium

[Warren G Landrum]

Pulled the RDB 7.2.1.2 for OpenVMS savesets down from the Oracle website to install on a HP Integrity rx6600 server running OpenVMS 8.3. Unzipped and copied (FTPed) savesets over to server. When I do the $@sys$update:vmsinstal, I get following error message:

" excessive error rate reading rdbv72120..."

I KNOW this error has to do with me having NOT set the file attributes of the savesets.( ie, $ set file/att=(rfm=fix,lrl=???,rat=none) or something like that. I just need to know the exact file atributes to set these savesets to as I have not been able to find them documented anywhere. Once I get this info, I'll be good...

Thanks in advance.

Warren

[Hein van den Heuvel]

Google: saveset fix openvms

There is a tool on the freeware kits.
And you can just dump the first block and figure it out.

I like my solution best :-)


--------- fixsavset.com -----------------
$IF p1.EQS."" THEN INQUIRE p1 "Save set file name ?"
$IF f$search(p1).EQS."" THEN EXIT
$WRITE SYS$OUTPUT " RFM was ", F$FILE(p1,"RFM"), ", MRS = ", -
F$FILE(p1,"MRS"), ", LRL = ", F$FILE(p1,"LRL"), "."
$SET FILE /ATTR=(RFM=FIX, MRS=44, LRL=44) 'p1 ! Easier for DCL
$OPEN/READ file 'p1
$READ file record
$CLOSE file
$mrs = F$CVSI(40*8,32,record)
$WRITE SYS$OUTPUT "Setting blocksize to: ",MRS
$SET FILE /ATTR=(RFM=FIX, MRS='mrs', LRL='mrs') 'p1


--------- check_savset.com -----------------

If you just want to look, without changing the file or the file attributes:


$IF p1.EQS."" THEN INQUIRE p1 "Save set file name ?"
$IF f$search(p1).EQS."" THEN EXIT
$IF F$FILE(p1,"MRS").GT.512 THEN GOTO no_can_do
$OPEN/READ file 'p1
$READ file record
$CLOSE file
$mrs = F$CVSI(40*8,32,record)
$WRITE SYS$OUTPUT "Backup blocksize used was: ",MRS
$EXIT
$no_can_do:
$type sys$input

The record size for the selected file is larger than 512.
This script cannot be used for that file.

$exit


Cheers,
Hein.

[labadie_1 · Accepted solution]

another procedure, give the saveset as P1

$ set noon
$ if p1.eqs."".or.f$search(p1).eqs."" then exit
$ ! put correct characteristics for a save set, and later the correct lrl
$ ! which will be very often 32256 or 9216
$ set file/attr=(rfm:fix,rat:none,mrs:32256,lrl:32256) 'p1
$ pipe bac/lis/ana 'p1/sav | sea sys$pipe "blocksize =" | -
( read SYS$PIPE TMP ; DEFINE/JOB/NOLOG TMP &TMP )
$ tmp1 = f$trnlnm("tmp","lnm$job","super",,)
$ loc = f$locate("=",tmp1)
$ blocks = f$extract(loc+2,5,tmp1)
$ set fil/attr=(lrl:'blocks,mrs:'blocks) 'p1
$ exit

[Warren G Landrum]

Labadie,

Created that com file and ran. Worked like a champ ! I am into the install.

Muchas Gracias !!!!

Warren

[Warren G Landrum]

Thred closed. Got answer from labadie !!

Warren